319 lines
12 KiB
Plaintext
319 lines
12 KiB
Plaintext
Function Prod_Spec_Actions(Action, CalcColName, FSList, Handle, Name, FMC, Record, Status, OrigRecord, Param1, Param2, Param3, Param4, Param5, Param6, Param7, Param8, Param9, Param10)
|
|
/***********************************************************************************************************************
|
|
|
|
This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
|
|
permission from Infineon.
|
|
|
|
Name : Prod_Spec_Actions
|
|
|
|
Description : Handles calculated columns and MFS calls for the current table.
|
|
|
|
Notes : This function uses @ID, @RECORD, and @DICT to make sure {ColumnName} references work correctly.
|
|
If called from outside of a calculated column these will need to be set and restored.
|
|
|
|
Parameters :
|
|
Action [in] -- Name of the action to be taken
|
|
CalcColName [in] -- Name of the calculated column that needs to be processed. Normally this should only be
|
|
populated when the CalcField action is being used.
|
|
FSList [in] -- The list of MFSs and the BFS name for the current file or volume. This is an @SVM
|
|
delimited array, with the current MFS name as the first value in the array, and the BFS
|
|
name as the last value. Normally set by a calling MFS.
|
|
Handle [in] -- The file handle of the file or media map being accessed. Note, this does contain the
|
|
entire handle structure that the Basic+ Open statement would provide. Normally set by a
|
|
calling MFS.
|
|
Name [in] -- The name (key) of the record or file being accessed. Normally set by a calling MFS.
|
|
FMC [in] -- Various functions. Normally set by a calling MFS.
|
|
Record [in] -- The entire record (for record-oriented functions) or a newly-created handle (for
|
|
"get handle" functions). Normally set by a calling MFS.
|
|
Status [in/out] -- Indicator of the success or failure of an action. Normally set by the calling MFS but
|
|
for some actions can be set by the action handler to indicate failure.
|
|
OrigRecord [in] -- Original content of the record being processed by the current action. This is
|
|
automatically being assigned by the WRITE_RECORD and DELETE_RECORD actions within
|
|
BASE_MFS.
|
|
Param1-10 [in/out] -- Additional request parameter holders
|
|
ActionFlow [out] -- Used to control the action chain (see the ACTION_SETUP insert for more information.)
|
|
Can also be used to return a special value, such as the results of the CalcField
|
|
method.
|
|
|
|
History : (Date, Initials, Notes)
|
|
07/28/10 dmb Original programmer.
|
|
10/13/10 dmb Fix logic to extract the file handle if file has an index
|
|
03/26/11 dmb Add logic to save and restore @FILE.ERROR
|
|
03/24/21 djs Moved code from PROD_SPEC form WRITE script event into WRITE_RECORD MFS call
|
|
|
|
***********************************************************************************************************************/
|
|
|
|
#pragma precomp SRP_PreCompiler
|
|
|
|
$insert LOGICAL
|
|
$insert FILE.SYSTEM.EQUATES
|
|
$insert ACTION_SETUP
|
|
$insert GAN_PARAM_CONFIG_EQUATES
|
|
$insert GAN_PARAMS_EQUATES
|
|
$insert PROD_SPEC_EQUATES
|
|
$insert RLIST_EQUATES
|
|
|
|
Equ Tab$ to \09\
|
|
Equ CRLF$ to \0D0A\
|
|
Equ LF$ to \0A\
|
|
Equ Comma$ to ','
|
|
|
|
Declare Function Database_Services, Gan_Services, Error_Services, Logging_Services, Environment_Services
|
|
Declare Subroutine Database_Services, obj_Prod_Spec, Error_Services, obj_Notes, Logging_Services
|
|
|
|
LogPath = Environment_Services('GetApplicationRootPath') : '\LogFiles\Indexing'
|
|
LogDate = Oconv(Date(), 'D4/')
|
|
LogTime = Oconv(Time(), 'MTS')
|
|
LogFileName = LogDate[7, 4] : '-' : LogDate[1, 2] : '-' : LogDate[4, 2] : ' PRS_PROP Index Log.csv'
|
|
Headers = 'Logging DTM' : @FM : 'PROD_SPEC Key ID'
|
|
objLog = Logging_Services('NewLog', LogPath, LogFileName, CRLF$, Comma$, Headers, '', False$, False$)
|
|
LoggingDTM = LogDate : ' ' : LogTime ; // Logging DTM
|
|
|
|
If KeyID then GoSub Initialize_System_Variables
|
|
|
|
Begin Case
|
|
|
|
Case Action _EQC 'CalculateColumn' ; GoSub CalculateColumn
|
|
Case Action _EQC 'READ_RECORD_PRE' ; GoSub READ_RECORD_PRE
|
|
Case Action _EQC 'READ_RECORD' ; GoSub READ_RECORD
|
|
Case Action _EQC 'READONLY_RECORD_PRE' ; GoSub READONLY_RECORD_PRE
|
|
Case Action _EQC 'READONLY_RECORD' ; GoSub READONLY_RECORD
|
|
Case Action _EQC 'WRITE_RECORD_PRE' ; GoSub WRITE_RECORD_PRE
|
|
Case Action _EQC 'WRITE_RECORD' ; GoSub WRITE_RECORD
|
|
Case Action _EQC 'DELETE_RECORD_PRE' ; GoSub DELETE_RECORD_PRE
|
|
Case Action _EQC 'DELETE_RECORD' ; GoSub DELETE_RECORD
|
|
Case Otherwise$ ; Status = 'Invalid Action'
|
|
|
|
End Case
|
|
|
|
If KeyID then GoSub Restore_System_Variables
|
|
|
|
If Assigned(ActionFlow) else ActionFlow = ACTION_CONTINUE$
|
|
|
|
Return ActionFlow
|
|
|
|
|
|
// ----- Calculated Columns --------------------------------------------------------------------------------------------
|
|
//
|
|
// The typical structure of a calculated column will look like this:
|
|
//
|
|
// Declare function TableName_Actions
|
|
//
|
|
// A = {COL1} ; * Reference as many data columns in this way to ensure the dictionary dependency is generated.
|
|
//
|
|
// @ANS = TableName_Actions('CalcField', 'CalcColName')
|
|
//
|
|
// ---------------------------------------------------------------------------------------------------------------------
|
|
|
|
CalculateColumn:
|
|
|
|
// Make sure the ActionFlow return variable is cleared in case nothing is calculated.
|
|
ActionFlow = ''
|
|
|
|
Begin Case
|
|
Case CalcColName EQ 'EXPORT_CONTROL' ; GoSub EXPORT_CONTROL
|
|
Case CalcColName EQ 'SPEC_TYPE' ; GoSub SPEC_TYPE
|
|
Case CalcColName EQ 'CURR_PART_NO' ; GoSub CURR_PART_NO
|
|
End Case
|
|
|
|
return
|
|
|
|
|
|
CURR_PART_NO:
|
|
|
|
EpiPartNo = ''
|
|
ProdVerNos = {PROD_VER_NO}
|
|
NumProdVer = DCount(ProdVerNos, @VM)
|
|
For ProdVerIndex = NumProdVer to 1 Step -1
|
|
ProdVerNo = ProdVerNos<0, ProdVerIndex>
|
|
Status = Xlate('PROD_VER', ProdVerNo, 'STATUS', 'X')
|
|
If Status EQ 'A' then EpiPartNo = Xlate('PROD_VER', ProdVerNo, 'EPI_PART_NO', 'X')
|
|
Until EpiPartNo NE ''
|
|
Next ProdVerIndex
|
|
ActionFlow = EpiPartNo
|
|
|
|
return
|
|
|
|
|
|
EXPORT_CONTROL:
|
|
|
|
PartNums = {EPI_PART_NO}
|
|
ExportControl = False$ ; // Assume false for now.
|
|
For Each PartNum in PartNums using @VM
|
|
ExportControl = Xlate('EPI_PART', PartNum, 'EXPORT_CONTROL', 'X')
|
|
If ExportControl NE True$ then ExportControl = False$
|
|
Until ExportControl EQ True$
|
|
Next PartNum
|
|
ActionFlow = ExportControl
|
|
|
|
return
|
|
|
|
|
|
SPEC_TYPE:
|
|
|
|
ModeCodes = {MODE_CODE}
|
|
ModeSigs = {MODE_SIG}
|
|
|
|
BEGIN CASE
|
|
CASE ModeSigs<0, 4> NE '' ; CurrMode = ModeCodes<0, 4>
|
|
CASE ModeSigs<0, 3> NE '' ; CurrMode = ModeCodes<0, 3>
|
|
CASE ModeSigs<0, 2> NE '' ; CurrMode = ModeCodes<0, 2>
|
|
CASE ModeSigs<0, 1> NE '' ; CurrMode = ModeCodes<0, 1>
|
|
Case Otherwise$ ; CurrMode = 1
|
|
END CASE
|
|
|
|
ActionFlow = CurrMode
|
|
|
|
return
|
|
|
|
|
|
// ----- MFS calls -----------------------------------------------------------------------------------------------------
|
|
|
|
READ_RECORD_PRE:
|
|
// In order to stop a record from being read in this action these lines of code must be used:
|
|
//
|
|
// OrigFileError = 100 : @FM : KeyID
|
|
// Status = 0
|
|
// Record = ''
|
|
// ActionFlow = ACTION_STOP$
|
|
return
|
|
|
|
READ_RECORD:
|
|
// In order to stop a record from being read in this action these lines of code must be used:
|
|
//
|
|
// OrigFileError = 100 : @FM : KeyID
|
|
// Status = 0
|
|
// Record = ''
|
|
return
|
|
|
|
READONLY_RECORD_PRE:
|
|
// In order to stop a record from being read in this action these lines of code must be used:
|
|
//
|
|
// OrigFileError = 100 : @FM : KeyID
|
|
// Status = 0
|
|
// Record = ''
|
|
// ActionFlow = ACTION_STOP$
|
|
return
|
|
|
|
READONLY_RECORD:
|
|
// In order to stop a record from being read in this action these lines of code must be used:
|
|
//
|
|
// OrigFileError = 100 : @FM : KeyID
|
|
// Status = 0
|
|
// Record = ''
|
|
return
|
|
|
|
WRITE_RECORD_PRE:
|
|
|
|
If {REACTOR_TYPE} EQ 'GAN' then
|
|
If {TECH_TYPE} EQ 'P' then
|
|
// Ensure Wafer Selection is set to CANDELA
|
|
Record<PROD_SPEC_ANKO_WAFER_SELECTION$> = 'CANDELA'
|
|
SaveRecord = Record
|
|
end
|
|
end
|
|
|
|
return
|
|
|
|
WRITE_RECORD:
|
|
|
|
* Pushes data to new table locations (e.g. PRS_PROP)
|
|
obj_Prod_Spec('PushTech', Name)
|
|
|
|
// Verify PRS_PROP -> PRS_LAYER relational index
|
|
IndexError = False$
|
|
PRSLayerKeys = {PRS_LAYER_KEY}
|
|
For each PRSLayerKey in PRSLayerKeys using @VM setting vPos
|
|
RelPRSPropKeys = Xlate('PRS_LAYER', PRSLayerKey, 'PRS_PROP_KEY', 'X')
|
|
LayerNo = Field(PRSLayerKey, '*', 2, 1)
|
|
Query = 'SELECT PRS_PROP WITH PS_NO EQ "':Name:'" AND WITH LAYER_NO EQ "':LayerNo:'"'
|
|
Flag = ''
|
|
GoSub ClearCursors
|
|
RList(Query, TARGET_ACTIVELIST$, '', '', Flag)
|
|
Done = False$
|
|
NumIndexKeys = 0
|
|
Loop
|
|
ReadNext PRSPropKey else Done = True$
|
|
Until Done
|
|
Locate PRSPropKey in RelPRSPropKeys using @VM setting vPos else
|
|
IndexError = True$
|
|
// Key is missing from indexed column for some reason, so trigger the index by
|
|
// deleting the record and writing it again.
|
|
PRSPropRec = Database_Services('ReadDataRow', 'PRS_PROP', PRSPropKey)
|
|
Database_Services('DeleteDataRow', 'PRS_PROP', PRSPropKey, True$, False$)
|
|
Database_Services('WriteDataRow', 'PRS_PROP', PRSPropKey, PRSPropRec, True$, False$, True$)
|
|
end
|
|
Repeat
|
|
Next PRSLayerKey
|
|
|
|
If IndexError then
|
|
// Log error and
|
|
LogData = ''
|
|
LogData<1> = LoggingDTM
|
|
LogData<2> = Name
|
|
Logging_Services('AppendLog', objLog, LogData, @RM, @FM, False$, '', '')
|
|
end
|
|
|
|
|
|
return
|
|
|
|
DELETE_RECORD_PRE:
|
|
return
|
|
|
|
DELETE_RECORD:
|
|
return
|
|
|
|
|
|
// ----- Internal Methods ----------------------------------------------------------------------------------------------
|
|
|
|
Initialize_System_Variables:
|
|
// Save these for restoration later
|
|
SaveDict = @DICT
|
|
SaveID = @ID
|
|
SaveRecord = @RECORD
|
|
OrigFileError = @FILE.ERROR
|
|
|
|
// Now make sure @DICT, ID, and @RECORD are populated
|
|
CurrentDictName = ''
|
|
If @DICT then
|
|
DictHandle = @DICT<1, 2>
|
|
Locate DictHandle in @TABLES(5) Using @FM Setting fPos then
|
|
CurrentDictName = Field(@TABLES(0), @FM, fPos, 1)
|
|
end
|
|
end
|
|
|
|
If CurrentDictName NE DictName then
|
|
Open DictName to @DICT else Status = 'Unable to initialize @DICT'
|
|
end
|
|
|
|
@ID = KeyID
|
|
If Record else
|
|
// Record might not have been passed in. Read the record from the database table just to make sure.
|
|
@FILE.ERROR = ''
|
|
Open TableName to hTable then
|
|
FullFSList = hTable[1, 'F' : @VM]
|
|
BFS = FullFSList[-1, 'B' : @SVM]
|
|
LastHandle = hTable[-1, 'B' : \0D\]
|
|
FileHandle = \0D\ : LastHandle[1, @VM]
|
|
|
|
Call @BFS(READO.RECORD, BFS, FileHandle, KeyID, FMC, Record, ReadOStatus)
|
|
end
|
|
end
|
|
@RECORD = Record
|
|
return
|
|
|
|
Restore_System_Variables:
|
|
Transfer SaveDict to @DICT
|
|
Transfer SaveID to @ID
|
|
Transfer SaveRecord to @RECORD
|
|
@FILE.ERROR = OrigFileError
|
|
return
|
|
|
|
ClearCursors:
|
|
For counter = 0 to 8
|
|
ClearSelect counter
|
|
Next counter
|
|
return
|
|
|
|
|