158 lines
6.9 KiB
Plaintext
158 lines
6.9 KiB
Plaintext
Function Reactservs_API(@API)
|
|
/***********************************************************************************************************************
|
|
|
|
This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
|
|
permission from SRP Computer Solutions, Inc.
|
|
|
|
Name : Reactservs_API
|
|
|
|
Description : API logic for the Reactservs resource.
|
|
|
|
Notes : All web APIs should include the API_SETUP insert. This will provide several useful variables:
|
|
|
|
HTTPMethod - The HTTP Method (Verb) submitted by the client (e.g., GET, POST, etc.)
|
|
APIURL - The URL for the API entry point (e.g., api.mysite.com/v1).
|
|
FullEndpointURL - The URL submitted by the client, including query params.
|
|
FullEndpointURLNoQuery - The URL submitted by the client, excluding query params.
|
|
EndpointSegment - The URL endpoint segment.
|
|
ParentURL - The URL path preceeding the current endpoint.
|
|
CurrentAPI - The name of this stored procedure.
|
|
|
|
Parameters :
|
|
API [in] -- Web API to process. Format is [APIPattern].[HTTPMethod]:
|
|
- APIPattern must follow this structure Reactservs[.ID.[<Property>]]
|
|
- HTTPMethod can be any valid HTTP method, e.g., GET, POST, PUT, DELETE, etc.
|
|
Examples:
|
|
- Reactservs.POST
|
|
- Reactservs.ID.PUT
|
|
- Reactservs.ID.firstName.GET
|
|
Response [out] -- Response to be sent back to the Controller (HTTP_MCP) or requesting procedure. Web API
|
|
services do not rely upon anything being returned in the response. This is what the
|
|
various services like SetResponseBody and SetResponseStatus services are for. A response
|
|
value is only helpful if the developers want to use it for debug purposes.
|
|
|
|
History : (Date, Initials, Notes)
|
|
07/29/22 djs Original programmer.
|
|
|
|
***********************************************************************************************************************/
|
|
|
|
#pragma precomp SRP_PreCompiler
|
|
|
|
$insert APP_INSERTS
|
|
$insert API_SETUP
|
|
$insert HTTP_INSERTS
|
|
|
|
Declare subroutine OI_Wizard_Services, SRP_JSON
|
|
Declare function React_Servs_Services, SRP_JSON
|
|
|
|
GoToAPI else
|
|
// The specific resource endpoint doesn't have a API handler yet.
|
|
HTTP_Services('SetResponseStatus', 204, 'This is a valid endpoint but a web API handler has not yet been created.')
|
|
end
|
|
|
|
Return Response OR ''
|
|
|
|
|
|
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
|
|
// Endpoint Handlers
|
|
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
|
|
|
|
|
|
// Endpoint to get all REACT_SERVS objects
|
|
API ReactServs.HEAD
|
|
API ReactServs.GET
|
|
|
|
StatusCode = 200
|
|
GoSub CreateHALCollection
|
|
|
|
end api
|
|
|
|
|
|
// Endpoint to get a single REACT_SERVS object
|
|
API ReactServs.ID.GET
|
|
|
|
StatusCode = 200
|
|
GoSub CreateHALItem
|
|
|
|
end api
|
|
|
|
|
|
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
|
|
// Internal GoSubs
|
|
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
|
|
|
|
|
|
//----------------------------------------------------------------------------------------------------------------------
|
|
// CreateHALItem
|
|
//
|
|
// Creates a HAL+JSON object based on the OpenInsight data row representation of the scan.
|
|
//----------------------------------------------------------------------------------------------------------------------
|
|
CreateHALItem:
|
|
|
|
ReactServID = EndpointSegment
|
|
ReactServJSON = React_Servs_Services('ConvertRecordToJSON', ReactServID, '', FullEndpointURL)
|
|
|
|
If Error_Services('NoError') then
|
|
HTTP_Services('SetResponseHeaderField', 'Content-Location', FullEndpointURL)
|
|
HTTP_Services('SetResponseBody', ReactServJSON, False$, 'application/hal+json')
|
|
If Assigned(Message) then
|
|
HTTP_Services('SetResponseStatus', StatusCode, Message)
|
|
end else
|
|
HTTP_Services('SetResponseStatus', StatusCode)
|
|
end
|
|
end else
|
|
Message = Error_Services('GetMessage')
|
|
HTTP_Services('SetResponseStatus', 500, 'Error in the ' : CurrentAPI : ' API. Message: ': Message)
|
|
end
|
|
|
|
return
|
|
|
|
|
|
//----------------------------------------------------------------------------------------------------------------------
|
|
// CreateHALCollection
|
|
//
|
|
// Creates a HAL+JSON collection based on OpenInsight data row representations.
|
|
//----------------------------------------------------------------------------------------------------------------------
|
|
CreateHALCollection:
|
|
|
|
JSONCollection = ''
|
|
Abort = False$
|
|
ReactServs = React_Servs_Services('GetReactServs')
|
|
If SRP_JSON(hJSONCollection, 'New', 'Object') then
|
|
If SRP_JSON(hReactServsArray, 'New', 'Array') then
|
|
For each ReactServID in ReactServs using @FM setting fPos
|
|
ReactServJSON = React_Servs_Services('ConvertRecordToJSON', ReactServID, '', FullEndpointURL:'/':ReactServID)
|
|
If Error_Services('NoError') then
|
|
If (SRP_JSON(hReactServ, 'Parse', ReactServJSON) EQ '') then
|
|
SRP_JSON(hReactServsArray, 'Add', hReactServ)
|
|
SRP_JSON(hReactServ, 'Release')
|
|
end
|
|
end else
|
|
Abort = True$
|
|
end
|
|
Until Abort
|
|
Next ReactorNo
|
|
If Abort EQ False$ then
|
|
SRP_JSON(hJSONCollection, 'Set', 'reactServs', hReactServsArray)
|
|
end
|
|
SRP_JSON(hReactServsArray, 'Release')
|
|
end
|
|
JSONCollection = SRP_JSON(hJSONCollection, 'Stringify', 'Styled')
|
|
SRP_JSON(hJSONCollection, 'Release')
|
|
end
|
|
|
|
If Error_Services('NoError') then
|
|
HTTP_Services('SetResponseHeaderField', 'Content-Location', FullEndpointURL)
|
|
HTTP_Services('SetResponseBody', JSONCollection, False$, 'application/hal+json')
|
|
If Assigned(Message) then
|
|
HTTP_Services('SetResponseStatus', StatusCode, Message)
|
|
end else
|
|
HTTP_Services('SetResponseStatus', StatusCode)
|
|
end
|
|
end else
|
|
Message = Error_Services('GetMessage')
|
|
HTTP_Services('SetResponseStatus', 500, 'Error in the ' : CurrentAPI : ' API. Message: ': Message)
|
|
end
|
|
|
|
return
|