Function Sched_Det_NG_Actions(Action, CalcColName, FSList, Handle, Name, FMC, Record, Status, OrigRecord, Param1, Param2, Param3, Param4, Param5, Param6, Param7, Param8, Param9, Param10)
#pragma precomp SRP_PreCompiler

/***********************************************************************************************************************

    This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
    permission from Infineon.

    Name        :   Sched_Det_NG_Actions

    Description :   Handles calculated columns and MFS calls for the current table.

    Notes       :   This function uses @ID, @RECORD, and @DICT to make sure {ColumnName} references work correctly.
                    If called from outside of a calculated column these will need to be set and restored.

    Parameters  :
        Action          [in] -- Name of the action to be taken
        CalcColName     [in] -- Name of the calculated column that needs to be processed. Normally this should only be
                                populated when the CalcField action is being used.
        FSList          [in] -- The list of MFSs and the BFS name for the current file or volume. This is an @SVM
                                delimited array, with the current MFS name as the first value in the array, and the BFS
                                name as the last value. Normally set by a calling MFS.
        Handle          [in] -- The file handle of the file or media map being accessed. Note, this does contain the
                                entire handle structure that the Basic+ Open statement would provide. Normally set by a
                                calling MFS.
        Name            [in] -- The name (key) of the record or file being accessed. Normally set by a calling MFS.
        FMC             [in] -- Various functions. Normally set by a calling MFS.
        Record          [in] -- The entire record (for record-oriented functions) or a newly-created handle (for
                                "get handle" functions). Normally set by a calling MFS.
        Status      [in/out] -- Indicator of the success or failure of an action. Normally set by the calling MFS but
                                for some actions can be set by the action handler to indicate failure.
        OrigRecord      [in] -- Original content of the record being processed by the current action. This is
                                automatically being assigned by the WRITE_RECORD and DELETE_RECORD actions within
                                BASE_MFS.
        Param1-10   [in/out] -- Additional request parameter holders
        ActionFlow     [out] -- Used to control the action chain (see the ACTION_SETUP insert for more information.)
                                Can also be used to return a special value, such as the results of the CalcField
                                method.

    History     :   (Date, Initials, Notes)
        02/25/21    djs     Initial coding. Adapted from SCHED_DET_ACTIONS. 

***********************************************************************************************************************/

$insert APP_INSERTS
$insert FILE.SYSTEM.EQUATES
$insert ACTION_SETUP
$insert WO_MAT_EQUATES
$insert WO_LOG_EQUATES
$insert SCHED_DET_NG_EQUATES
$insert REACTOR_EQUATES

Declare function    Error_Services, Database_Services, Memory_Services, Datetime
Declare subroutine  Error_Services, Database_Services, Memory_Services, Schedule_Services

If KeyID then GoSub Initialize_System_Variables

Begin Case
	
	Case Action _EQC 'CalculateColumn'      ;   GoSub CalculateColumn
	Case Action _EQC 'READ_RECORD_PRE'      ;   GoSub READ_RECORD_PRE
	Case Action _EQC 'READ_RECORD'          ;   GoSub READ_RECORD
	Case Action _EQC 'READONLY_RECORD_PRE'  ;   GoSub READONLY_RECORD_PRE
	Case Action _EQC 'READONLY_RECORD'      ;   GoSub READONLY_RECORD
	Case Action _EQC 'WRITE_RECORD_PRE'     ;   GoSub WRITE_RECORD_PRE
	Case Action _EQC 'WRITE_RECORD'         ;   GoSub WRITE_RECORD
	Case Action _EQC 'DELETE_RECORD_PRE'    ;   GoSub DELETE_RECORD_PRE
	Case Action _EQC 'DELETE_RECORD'        ;   GoSub DELETE_RECORD
	Case Otherwise$                         ;   Status = 'Invalid Action'
		
End Case

If KeyID then GoSub Restore_System_Variables

If Assigned(ActionFlow) else ActionFlow = ACTION_CONTINUE$

Return ActionFlow


// ----- Calculated Columns --------------------------------------------------------------------------------------------
//
// The typical structure of a calculated column will look like this:
//
// Declare function TableName_Actions
//
// A = {COL1} ; * Reference as many data columns in this way to ensure the dictionary dependency is generated.
//
// @ANS = TableName_Actions('CalcField', 'CalcColName')
//
// ---------------------------------------------------------------------------------------------------------------------

CalculateColumn:
	// Make sure the ActionFlow return variable is cleared in case nothing is calculated.
	ActionFlow = ''
	
	Begin Case
		Case CalcColName EQ 'EVENT_DURATION'  ; GoSub EVENT_DURATION
		Case CalcColName EQ 'HARD_BLOCK'      ; GoSub HARD_BLOCK
		Case CalcColName EQ 'SOFT_BLOCK'      ; GoSub SOFT_BLOCK
		Case CalcColName EQ 'REACT_TYPE'      ; GoSub REACT_TYPE
	End Case
	
return


EVENT_DURATION:
	
	ActionFlow = {STOP_DTM} - {START_DTM}
	
return


HARD_BLOCK:
	
	If {BLOCK_OUT} EQ True$ then
		HardBlockTypes = Database_Services('ReadDataRow', 'APP_INFO', 'SCHED_HARD_BLOCKS')
		Locate {BLOCK_OUT_TYPE} in HardBlockTypes using @FM setting fPos then
			ActionFlow = True$
		end else
			ActionFlow = False$
		end
	end else
		ActionFlow = False$
	end
	
return


SOFT_BLOCK:
	
	If {BLOCK_OUT} EQ True$ then
		SoftBlockTypes = Database_Services('ReadDataRow', 'APP_INFO', 'SCHED_SOFT_BLOCKS')
		Locate {BLOCK_OUT_TYPE} in SoftBlockTypes using @FM setting fPos then
			ActionFlow = True$
		end else
			ActionFlow = False$
		end
	end else
		ActionFlow = False$
	end
	
return


REACT_TYPE:
	
	ActionFlow = Xlate('REACTOR', {REACT_NO}, 'REACT_TYPE', 'X')
	
return


// ----- MFS calls -----------------------------------------------------------------------------------------------------

READ_RECORD_PRE:
	
	// Somewhere there is a bug that can cause multiple stop dtms to be set for an event.
	// This is a stopgap solution until the bug is found.
	StopDtm = Record<SCHED_DET_NG.STOP_DTM$>
	If DCount(StopDtm, @VM) GT 1 then
		StopDTM                        = StopDtm<0, 1>
		Record<SCHED_DET_NG.STOP_DTM$> = StopDtm
	end
	
return

READ_RECORD:
	
	// Somewhere there is a bug that can cause multiple stop dtms to be set for an event.
	// This is a stopgap solution until the bug is found.
	StopDtm = Record<SCHED_DET_NG.STOP_DTM$>
	If DCount(StopDtm, @VM) GT 1 then
		StopDTM                        = StopDtm<0, 1>
		Record<SCHED_DET_NG.STOP_DTM$> = StopDtm
	end
	
return

READONLY_RECORD_PRE:
	// In order to stop a record from being read in this action these lines of code must be used:
	//
	//    OrigFileError   = 100 : @FM : KeyID
	//    Status          = 0
	//    Record          = ''
	//    ActionFlow      = ACTION_STOP$
return

READONLY_RECORD:
	// In order to stop a record from being read in this action these lines of code must be used:
	//
	//    OrigFileError   = 100 : @FM : KeyID
	//    Status          = 0
	//    Record          = ''
return

WRITE_RECORD_PRE:
	
	// Somewhere there is a bug that can cause multiple stop dtms to be set for an event.
	// This is a stopgap solution until the bug is found.
	StopDtm = Record<SCHED_DET_NG.STOP_DTM$>
	If DCount(StopDtm, @VM) GT 1 then
		StopDTM                            = StopDtm<0, 1>
		SaveRecord<SCHED_DET_NG.STOP_DTM$> = StopDtm
	end
	
	If OrigRecord<SCHED_DET_NG.EVENT_TOTAL_WFRS$> NE Record<SCHED_DET_NG.EVENT_TOTAL_WFRS$> then
        LogData    = ''
        LogData<1> = OConv(Datetime(), 'DT2/^H')
        LogData<2> = 'SCHED_DET_NG_ACTIONS'
        LogData<3> = 'Event ':Name:' for work order ':Record<SCHED_DET_NG.WO_NO$>:' on reactor ':Record<SCHED_DET_NG.REACT_NO$>:' quantity changed from ':OrigRecord<SCHED_DET_NG.EVENT_TOTAL_WFRS$>:' to ':Record<SCHED_DET_NG.EVENT_TOTAL_WFRS$>:'.'
        Schedule_Services('LogActivity', Record<SCHED_DET_NG.REACT_NO$>, LogData, False$)
	end
	
return

WRITE_RECORD:
	
	// Somewhere there is a bug that can cause multiple stop dtms to be set for an event.
	// This is a stopgap solution until the bug is found.
	StopDtm = Record<SCHED_DET_NG.STOP_DTM$>
	If DCount(StopDtm, @VM) GT 1 then
		StopDTM                            = StopDtm<0, 1>
		SaveRecord<SCHED_DET_NG.STOP_DTM$> = StopDtm
	end
	
return

DELETE_RECORD_PRE:
return

DELETE_RECORD:
	
	ReactRec  = Database_Services('ReadDataRow', 'REACTOR', {REACT_NO})
	EventList = ReactRec<REACTOR_SCHED_EVENTS$>
	Locate Name in EventList using @VM setting vPos then
		EventList                       = Delete(EventList, 0, vPos, 0)
		ReactRec<REACTOR_SCHED_EVENTS$> = EventList
		Database_Services('WriteDataRow', 'REACTOR', {REACT_NO}, ReactRec, True$, False$, True$)
	end
	
return


// ----- Internal Methods ----------------------------------------------------------------------------------------------

Initialize_System_Variables:
	// Save these for restoration later
	SaveDict        = @DICT
	SaveID          = @ID
	SaveRecord      = @RECORD
	OrigFileError   = @FILE.ERROR
	
	// Now make sure @DICT, ID, and @RECORD are populated
	CurrentDictName = ''
	If @DICT then
		DictHandle = @DICT<1, 2>
		Locate DictHandle in @TABLES(5) Using @FM Setting fPos then
			CurrentDictName = Field(@TABLES(0), @FM, fPos, 1)
		end
	end
	
	If CurrentDictName NE DictName then
		Open DictName to @DICT else Status = 'Unable to initialize @DICT'
	end    
	
	@ID = KeyID
	If Record else
		// Record might not have been passed in. Read the record from the database table just to make sure.
		@FILE.ERROR     = ''
		Open TableName to hTable then
			FullFSList  = hTable[1, 'F' : @VM]
			BFS         = FullFSList[-1, 'B' : @SVM]
			LastHandle  = hTable[-1, 'B' : \0D\]
			FileHandle  = \0D\ : LastHandle[1, @VM]
			
			Call @BFS(READO.RECORD, BFS, FileHandle, KeyID, FMC, Record, ReadOStatus)
		end
	end
	@RECORD = Record
return

Restore_System_Variables:
	Transfer SaveDict   to @DICT
	Transfer SaveID     to @ID
	Transfer SaveRecord to @RECORD
	@FILE.ERROR = OrigFileError
return