Function NDW_Wafers_Removed_Rds_Prompt_Events(CtrlEntId, Event, @PARAMS)

#pragma precomp SRP_PreCompiler
#Window NDW_WAFERS_REMOVED_RDS_PROMPT

$insert APP_INSERTS
$insert EVENT_SETUP

$insert Message_Box_Equates

Declare subroutine Placedialog, Message_Box

SubclassInfo    = Form_Services('FindSubclassControl')
Subclass        = SubclassInfo<1>

// Update the arguments so that the OpenInsight OLE event will treate the ActiveX event as a native event handler.
If Event EQ 'OLE' then
    Transfer Event to OIEvent
    Transfer Param1 to Event
    Transfer Param2 to Param1
    Transfer Param3 to Param2
*    Transfer Param4 to Param3
*    Transfer Param5 to Param4
*    Transfer Param6 to Param5
*    Transfer Param7 to Param6
*    Transfer Param8 to Param7
end

GoToEvent Event for CtrlEntID

Return EventFlow else EVENT_CONTINUE$

Event WINDOW.CREATE(CreateParam)
	Placedialog(-2, -2)
end event

Event PUB_SUBMIT.CLICK()
	SelectedLoadLocks = ''
	
	LeftIsChecked = Get_Property(@Window:'.CHB_LEFT', 'CHECK')
	RightIsChecked = Get_Property(@Window:'.CHB_RIGHT', 'CHECK')
	
	If LeftIsChecked then SelectedLoadLocks = 'L'
	If RightIsChecked then
		If LeftIsChecked then
			SelectedLoadLocks := @VM
		end
		SelectedLoadLocks := 'R'
	end	
	If (LeftIsChecked EQ False$) and (RightIsChecked EQ False$) then
		Message_Box(@Window, "You must select at least one load lock", "Error", MSG_ICON_EXCLAM$)
		return
	end
	
    End_Dialog(@Window, SelectedLoadLocks)
end event