Function NDW_USER_OVERRIDE_EVENTS(CtrlEntId, Event, @PARAMS)
/***********************************************************************************************************************

    This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
    permission from Infineon.

    Name        :   NDW_USER_OVERRIDE_EVENTS
    Description :   This function acts as a commuter module for all events related to this window.

    Notes       :   Commuter Modules are automatically called from the Promoted_Events function which is called by the
                    application-specific promoted event handler. This makes it possible to add QuickEvents that need to
                    execute Basic+ logic without having use the Form Designer to make the association, although this is
                    limited to the events which are currently promoted.

                    If the form needs to call the commuter module directly then the QuickEvent parameters should be
                    formatted like this:

                        '@SELF','@EVENT',['@PARAM1','@PARAMx']

    Parameters  :
        CtrlEntId   [in] -- The fully qualified name of the control calling the promoted event
        Event       [in] -- The event being executed. See the Notes section regarding "PRE" events
        Param1-15   [in] -- Additional event parameter holders
        EventFlow  [out] -- Set to 1 or 0 so the calling event knows whether or not to chain forward. See comments in
                            EVENT_SETUP insert

    History     :   (Date, Initials, Notes)
        10/19/23	djm		Create initial commuter module.

***********************************************************************************************************************/

#pragma precomp SRP_PreCompiler


$insert APP_INSERTS
$insert EVENT_SETUP
$insert MSG_EQUATES
 
Declare subroutine  SRP_Show_Window
Declare function Security_Services, Active_Directory_Services


// Update the arguments so that the OpenInsight OLE event will treate the ActiveX event as a native event handler.
If Event EQ 'OLE' then
    Transfer Event to OIEvent
    Transfer Param1 to Event
    Transfer Param2 to Param1
    Transfer Param3 to Param2
*    Transfer Param4 to Param3
*    Transfer Param5 to Param4
*    Transfer Param6 to Param5
*    Transfer Param7 to Param6
*    Transfer Param8 to Param7
end

GoToEvent Event for CtrlEntID

Return EventFlow else EVENT_CONTINUE$


////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Events
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

Event WINDOW.CREATE(CreateParam)
    
    If CreateParam NE '' then
        Set_Property(@Window : '.TXT_ALLOWED_USER', 'TEXT', CreateParam)
    end else
        Set_Property(@Window : '.TXT_ALLOWED_USER', 'TEXT', 'Error retreiving LSL User. Please try again.')
    end
    GoSub Setup_OLE_Controls
    SRP_Show_Window(@Window, '', 'C', 'C', 1, '', False$, False$)

end event


Event WINDOW.CLOSE(CancelFlag)
    
    Result      = FALSE$
    End_Dialog(@Window, Result)
    
end event


Event EDL_USERNAME.CHAR(VirtCode, ScanCode, CtrlKey, ShiftKey, AltKey)

    Form_Services('CloseControlMessage', CtrlEntId)
    Username    = Get_Property(CtrlEntId, 'TEXT')
    Password    = Get_Property(@Window : '.EDL_PASSWORD', 'TEXT')
    If (Username NE '') AND (Password NE '') then
        Set_Property(@Window : '.PUB_OK', 'ENABLED', True$)
    end else
        Set_Property(@Window : '.PUB_OK', 'ENABLED', False$)
    end

end event

Event EDL_PASSWORD.CHAR(VirtCode, ScanCode, CtrlKey, ShiftKey, AltKey)

    PopupVis = Get_Property(@Window:'.OLE_POPUP', "OLE.Visible")
    If PopupVis then Form_Services('CloseControlMessage', CtrlEntId)
    Username    = Get_Property(@Window : '.EDL_USERNAME', 'TEXT')
    Password    = Get_Property(CtrlEntId, 'TEXT')
    If (Username NE '') AND (Password NE '') then
        Set_Property(@Window : '.PUB_OK', 'ENABLED', True$)
    end else
        Set_Property(@Window : '.PUB_OK', 'ENABLED', False$)
    end

end event

Event PUB_OK.CLICK()
    
    Result       = FALSE$
    ValidUser    =  Get_Property(@Window : '.TXT_ALLOWED_USER', 'TEXT')
    If ValidUser NE 'Error retreiving LSL User. Please try again.' then
        Username     = Get_Property(@Window : '.EDL_USERNAME', 'TEXT')
        Password     = Get_Property(@Window : '.EDL_PASSWORD', 'TEXT')
        Domain = 'INFINEON'
        EnteredUser = Security_Services('GetLSLUser', Username)
        If ValidUser EQ EnteredUser then
            // Correct User, move onto check password
            Result = Active_Directory_Services('AuthenticateUser', Username, Password, Domain)
        end else
            // Wrong User
            Msg(@Window, 'Invalid credentials.')
            End_Dialog(@Window, Result)
        end
        End_Dialog(@Window, Result)
    end else
        Msg(@Window, 'Error retreiving LSL User. Please try again.')
        End_Dialog(@Window, Result)
    end
    
end event


Event PUB_CANCEL.CLICK()

    Result      = ''
    End_Dialog(@Window, Result)

end event


////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Internal GoSubs
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

Setup_OLE_Controls:

    Qualify     = ''
    Qualify<1>  = 1
    Qualify<4>  = 0

return