Compile function Math_Services(@Service, @Params)
/***********************************************************************************************************************

    Name        :   Math_Services

    Description :   Handler program for all math services.

    Notes       :   Application errors should be logged using the Error Services module. There are a few methodological
                    assumptions built into way errors are managed which are important to understand in order to properly
                    work with Error Services:

                    - The term 'top' refers to the originating procedure of a call stack and the term 'bottom' refers to
                      the last routine (or the current routine) within a call stack. Within the OpenInsight Debugger
                      this will appear backwards since the originating procedure always appears at the bottom of the
                      list and the current routine appears at the top of the list. We are using this orientation because
                      it is common to refer to the process of calling other procedures as 'drilling down'.

                    - The reason for defining the orientation of the call stack is because Error_Services allows for
                      multiple error conditions to be appended to an original error. In most cases this will happen when
                      a procedure at the bottom of the stack generates an error condition and then returns to its
                      calling procedure. This higher level procedure can optionally add more information relevant to
                      itself. This continues as the call stack 'bubbles' its way back to the top to where the
                      originating procedure is waiting.

                    - Native OpenInsight commands that handle errors (e.g., Set_Status, Set_FSError, Set_EventStatus)
                      preserve their error state until explicitly cleared. This can hinder the normal execution of code
                      since subsequent procedures (usually SSPs) will fail if a pre-existing error condition exists.
                      Our philosophy is that error conditions should automatically be cleared before a new procedure
                      is executed to avoid this problem. However, the nature of Basic+ does not make this easy to
                      automate for any given stored procedure. Therefore, if a stored procedure wants to conform to our
                      philosophy then it should include a call into the 'Clear' service request at the top of the
                      program. Alternatively this can be done through a common insert (see SERVICE_SETUP for example.)

                    - Service modules will use the SERVICE_SETUP insert and therefore automatically clear out any
                      error conditions that were set before.

    Parameters  :
        Service         [in] -- Name of the service being requested
        Param1-10   [in/out] -- Additional request parameter holders
        Response       [out] -- Response to be sent back to the Controller (MCP) or requesting procedure

    Metadata    :

    History     :   (Date, Initials, Notes)
        11/12/20    djs     Original programmer.
														

***********************************************************************************************************************/
#pragma precomp SRP_PreCompiler
$insert LOGICAL
$insert SERVICE_SETUP

Declare function SRP_Array, Math_Services

GoToService else
    Error_Services('Set', Service : ' is not a valid service request within the ' : ServiceModule : ' services module.')
end

Return Response or ""

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Service Parameter Options
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
Options STD_DEV_TYPES        = 'SAMPLE','POPULATION'

//-----------------------------------------------------------------------------
// SERVICES
//-----------------------------------------------------------------------------

Service GetStdDev(ValueList, StdDevType=STD_DEV_TYPES)
    StdDev = 0
    If ValueList NE '' then       
        If StdDevType EQ '' then StdDevType = 'SAMPLE'    
        Avg        = 0
        Total      = 0
        Deviations = ''
        ValueList  = SRP_Array('Clean', ValueList, 'Trim', @VM)
        ValueCount = DCount(ValueList, @VM)
        If ValueCount GT 0 then
            For each Value in ValueList using @VM setting vPos
                Total += Value
            Next Value
            Avg = Total / ValueCount
            // Calculate Std Dev
            For each Value in ValueList using @VM setting vPos
                Deviation           = Value - Avg
                Deviations<0, vPos> = Deviation ** 2
            Next Value
            DevsSum = Sum(Deviations)
            If StdDevType EQ 'SAMPLE' then
                // Std Dev for a sample, not population
                If (ValueCount - 1) GT 0 then
                    Variance = DevsSum / (ValueCount - 1)
                    StdDev   = Variance ** 0.5
                end  
            end else
                // Std Dev for a population
                Variance = DevsSum / ValueCount
                StdDev   = Variance ** 0.5
            end
            Response = StdDev
        end
    end
    
End Service


Service GetCoefficientOfVariation(ValueList, StdDevType=STD_DEV_TYPES)
    
    ValueList = SRP_Array('Clean', ValueList, 'Trim', @VM)
    If ValueList NE '' then       
        StdDev    = Math_Services('GetStdDev', ValueList, StdDevType)
        NumValues = DCount(ValueList, @VM)
        Total     = Sum(ValueList)
        Avg       = Total / NumValues
        CV        = StdDev / Avg
        Response  = CV    
    end
    
end service