Function Createnewtestwaferlot_API(@API)
/***********************************************************************************************************************

    This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
    permission from SRP Computer Solutions, Inc.

    Name        :   Createnewtestwaferlot_API

    Description :   API logic for the Createnewtestwaferlot resource.

    Notes       :   All web APIs should include the API_SETUP insert. This will provide several useful variables:

                        HTTPMethod              - The HTTP Method (Verb) submitted by the client (e.g., GET, POST, etc.)
                        APIURL                  - The URL for the API entry point (e.g., api.mysite.com/v1).
                        FullEndpointURL         - The URL submitted by the client, including query params.
                        FullEndpointURLNoQuery  - The URL submitted by the client, excluding query params.
                        EndpointSegment         - The URL endpoint segment.
                        ParentURL               - The URL path preceeding the current endpoint.
                        CurrentAPI              - The name of this stored procedure.

    Parameters  :
        API             [in] -- Web API to process. Format is [APIPattern].[HTTPMethod]:
                                    - APIPattern must follow this structure Createnewtestwaferlot[.ID.[<Property>]]
                                    - HTTPMethod can be any valid HTTP method, e.g., GET, POST, PUT, DELETE, etc.
                                Examples:
                                    - Createnewtestwaferlot.POST
                                    - Createnewtestwaferlot.ID.PUT
                                    - Createnewtestwaferlot.ID.firstName.GET
        Response       [out] -- Response to be sent back to the Controller (HTTP_MCP) or requesting procedure. Web API
                                services do not rely upon anything being returned in the response. This is what the
                                various services like SetResponseBody and SetResponseStatus services are for. A response
                                value is only helpful if the developers want to use it for debug purposes.

    History     :   (Date, Initials, Notes)
        10/21/24    xxx     Original programmer.

***********************************************************************************************************************/

#pragma precomp SRP_PreCompiler

Declare function OI_Wizard_Services, Lot_Services

$insert APP_INSERTS
$insert API_SETUP
$insert HTTP_INSERTS
$Insert OI_Wizard_Equates

GoToAPI else
    // The specific resource endpoint doesn't have a API handler yet.
    HTTP_Services('SetResponseStatus', 204, 'This is a valid endpoint but a web API handler has not yet been created.')
end

Return Response OR ''


////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Endpoint Handlers
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////


API createnewtestwaferlot.POST
    //LotType, ProdName, LotQty, VendorPartNo, VendorLotNo, VendorCode, Username, PrinterID
    OIWizardID = ''
    Cookies    = HTTP_Services('GetHTTPCookie')
    For each Cookie in Cookies using ';'
        Key = Field(Cookie, '=', 1)
        If Key EQ 'sessionID' then
            OIWizardID = Field(Cookie, '=', 2)
        end
    Next Cookie
    ValidSession = OI_Wizard_Services('ValidateSession', OIWizardID)
    If ValidSession then
        // Check if payload has the required information to create a react mode change record
        Body = HTTP_Services('GetHTTPPostString')
        If Body NE '' then
            // The POST string will have been encoded so use percent (URL) decoding.
            //ReactModeJSON = HTTP_Services('DecodePercentString', Body)
            NewTWLotJson  = HTTP_Services('DecodePercentString', Body)
            ParseResponse = SRP_JSON(hNewTWLotJson, 'PARSE', NewTWLotJson)
            
            If (ParseResponse EQ '') then
                TWLotObject  = ''
                TWLotObject  = SRP_JSON(hNewTWLotJson, 'Get', 'NewTWLot')
                LotType      = 'TW'
                ProdName     = SRP_JSON(TWLotObject, 'GetValue', 'ProdName')
                LotQty       = SRP_JSON(TWLotObject, 'GetValue', 'LotQty')
                VendorPartNo = SRP_JSON(TWLotObject, 'GetValue', 'VendorPartNo')
                VendorLotNo  = SRP_JSON(TWLotObject, 'GetValue', 'VendorLotNo')
                VendorCode   = SRP_JSON(TWLotObject, 'GetValue', 'VendorCode')
                Username     = Xlate('OI_WIZARD', OIWizardID, OI_WIZARD.EMPLOYEE_ID$, 'X')
                PrinterID    = 'WEB'
                SRP_JSON(TWLotObject, 'Release')
                LotId        = Lot_Services('CreateNewLot', LotType, ProdName, LotQty, VendorPartNo, VendorLotNo, VendorCode, Username, PrinterID) 
                If Error_Services('NoError') And RowExists('LOT', LotId) then
                    Message = 'Create TW Lot Successful: New Lot ID - ' : LotId
                    GoSub CreateHALItem
                end else
                    HTTP_Services('SetResponseStatus', 400, Error_Services('GetMessage'))
                end
                SRP_Json(hNewTWLotJson, 'Release')
            end else
                // Error parsing JSON
                HTTP_Services('SetResponseStatus', 400, 'Unable to parse the JSON data from the request.')
            end
        end else
            // No JSON payload sent with request
            If SRP_JSON(hTemplateJSON, 'New', 'Object', 'Template') then
                SRP_JSON(hTemplateJSON, 'SetValue', 'ProdName', '')
                SRP_JSON(hTemplateJSON, 'SetValue', 'LotQty', '')
                SRP_JSON(hTemplateJSON, 'SetValue', 'VendorPartNo', '')
                SRP_JSON(hTemplateJSON, 'SetValue', 'VendorLotNo', '')
                SRP_JSON(hTemplateJSON, 'SetValue', 'VendorCode', '')
                JSONTemplate = SRP_JSON(hTemplateJSON, 'Stringify', 'Styled')
                SRP_JSON(hTemplateJSON, 'Release')
                HTTP_Services('SetResponseBody', JSONTemplate, False$, 'application/hal+json')
            end
            HTTP_Services('SetResponseStatus', 400, 'JSON object is missing in the body of the request.')
        end
    end else
        HTTP_Services('SetResponseStatus', 401, 'Invalid session. Reauthentication required.')
    end
end api

//----------------------------------------------------------------------------------------------------------------------
// CreateHALItem
//
// Creates a HAL+JSON object based on the OpenInsight data row representation.
//----------------------------------------------------------------------------------------------------------------------
CreateHALItem:
    
    LotJson = Lot_Services('ConvertLotRecordToJson', LotId, FullEndpointURL, CurrUser , 0)

    If Error_Services('NoError') then
        StatusCode = 200
        HTTP_Services('SetResponseHeaderField', 'Content-Location', FullEndpointURL)
        HTTP_Services('SetResponseBody', LotJson, False$, 'application/hal+json')
        If Assigned(Message) then
            HTTP_Services('SetResponseStatus', StatusCode, Message)
        end else
            HTTP_Services('SetResponseStatus', StatusCode)
        end
    end else
        Message = Error_Services('GetMessage')          
        HTTP_Services('SetResponseStatus', 500, 'Error in the ' : CurrentAPI : ' API. Message: ': Message)
    end

return