COMPILE FUNCTION COC_SRPT1() 

declare function msg, set_property, send_event, dialog_box, utility, get_property
declare function set_printer, PrintSetup, obj_Install
declare subroutine rlist, or_view, activate_save_select, yield
declare subroutine order_srpt1

$INSERT RLIST_EQUATES
$INSERT MSG_EQUATES
$INSERT OIPRINT_EQUATES
$INSERT RPT_CFG_EQU
$INSERT PRINTSETUP_EQUATES

TimeX = OCONV(Time(),'MTS')

CrLf = Char(13):Char(10) 
CurDte = OCONV(Date(),"D4/")

ReportID = "COC001_SRPTCFG"
ReportControl = "COC_SRPT1"
TableName = 'COC'
ListsId = ReportControl:'*':@station
TtlLin1 = ''
TtlLin2 = ''
TtlLin3 = ''
TtlLin4 = ''

open 'CONFIG' to ConfigTable else
    Void = msg( '', 'Unable to open CONFIG...' )
    return 0
end

Read SRptConfig From ConfigTable,ReportID Else
   Void = msg( '', 'Unable to read ': ReportID:' From CONFIG table!' )
   return 0
End

Params = dialog_box( ReportControl, @window, '*CENTER' )

if Params = 'CANCEL' or Params = '' then
    return 0
end



convert '*' to @fm in Params
BegDte         = Params<1>
EndDte         = Params<2>

Void = utility( 'CURSOR', 'H' )

WithStmt = 'SELECT ':TableName:' '
WthSwt = 0

BEGIN CASE
	CASE BegDte = EndDte AND BegDte NE '' AND EndDte NE ''
		TtlLin2 = 'Ship Date:':BegDte
		WithStmt :=  " WITH SHIP_DT = '":BegDte:"'"
		WthSwt = 1
		
	CASE BegDte and EndDte
		TtlLin2 = 'Ship Dates: From ':BegDte:' To ':EndDte
		WithStmt :=  " WITH SHIP_DT FROM '": BegDte:"' TO '":EndDte: "' "
		WthSwt = 1
		
	CASE BegDte
		TtlLin2 = 'Ship Dates: From ':BegDte:' To ':CurDte
		WithStmt := " WITH SHIP_DT GE '":BegDte:"' "
		WthSwt = 1
		
	CASE EndDte
		TtlLin2 = 'Ship Dates: From Earliest To ':EndDte
		WithStmt := " WITH SHIP_DT LE '":EndDte:"' "
		WthSwt = 1
		
	CASE 1
		TtlLin2 = 'Entry Dates: ALL'
      
END CASE

rlist( WithStmt, target_savelist$, ListsId, '', '' )
activate_save_select( ListsId )

Script = SRptConfig<SlistScript$>

RptWdt = SRptConfig<Width$>

Title	= obj_Install('Get_Prop','Company'):' ':SRptConfig<Title$>
Margin	=  INT((RptWdt - LEN(Title))/2)
LMargin = Margin - 10		;* 10 equals length of the date
RMargin = Margin - 8		;* 8 equals length of 'Page....'
Title = OCONV(Date(),'D4/'):SPACE(LMargin):Title:SPACE(RMargin):"Page'PP''L'"

SWAP '~Title~' WITH Title IN Script

TitleLine2 = TtlLin2
TitleLine3 = TtlLin3
TitleLine4 = TtlLin4

IF TitleLine2 NE '' THEN
	Margin = INT((RptWdt - LEN(TitleLine2))/2)
	LMargin = Margin - 7	;* 7 equals length of time (12:15PM)
	RMargin = Margin
	TitleLine2 = OCONV(Time(),'MTH'):SPACE(LMargin):TitleLine2:SPACE(RMargin)
	SWAP '~SecondTitleLine~'  WITH TitleLine2 IN Script
END ELSE
	SWAP '~SecondTitleLine~' WITH '' IN Script
END	

IF TitleLine3 NE '' THEN
	Margin = INT((RptWdt - LEN(TitleLine3))/2)
	SWAP '~ThirdTitleLine~'  WITH "'L'":TitleLine3 IN Script
END ELSE
	SWAP '~ThirdTitleLine~' WITH '' IN Script
END

IF TitleLine4 NE '' THEN
	Margin = INT((RptWdt - LEN(TitleLine4))/2)
	SWAP '~FourthTitleLine~'  WITH "'L'":TitleLine4 IN Script
END ELSE
	SWAP '~FourthTitleLine~' WITH '' IN Script
END


* Added after upgrade to OI4.13a to reset default printer in OIPI32 engine.

PrintCount	= PrintSetup(PRN_GET$,'',Printers,DefaultPrinter)
CONVERT ',' TO @FM IN DefaultPrinter
DefPrintPath = DefaultPrinter<1>:@FM:DefaultPrinter<3>

Void = set_printer( 'INIT', '', '', .63:@fm:.63:@fm:.25:@fm:'', 0,'',DefPrintPath )
Void = Set_Printer('TERM')

call slist( Script )
Void = utility( 'CURSOR', 'A' )



RETURN 0