compile function AC_SRPT1() 
begin condition
pre:
post:
end condition
declare function msg, set_property, send_event, dialog_box, utility, get_property, PrintSetup, Set_Printer
declare function set_printer, obj_Install
declare subroutine rlist, or_view, activate_save_select, yield
declare subroutine order_srpt1
$insert rlist_equates
$insert msg_equates
$insert oiprint_equates
$insert rpt_cfg_equ
$INSERT PRINTSETUP_EQUATES

TimeX = Oconv(Time(),'MTS')

CrLf = Char(13):Char(10) 
CurDte = OCONV(Date(),"D4/")

ReportID = "AC001_SRPTCFG"
ReportControl = "AC_SRPT1"
TableName = 'ANNUAL_CONTRACTS'

open 'CONFIG' to ConfigTable else
    Void = msg( '', 'Unable to open CONFIG...' )
    return 0
end

Read SRptConfig From ConfigTable,ReportID Else
   Void = msg( '', 'Unable to read ': ReportID:' From CONFIG table!' )
   return 0
End

Params = dialog_box( ReportControl, @window, '*CENTER' )

if Params = 'CANCEL' or Params = '' then
    return 0
end
open 'SYSLISTS' to SysListsTable else
   Void = msg( '', 'Unable to open SYSLISTS...' )
   return 0
end
ListsId = ReportControl:'*':@station
write '' on SysListsTable, ListsId else
   Void = msg( '', 'Unable to clear SYSLISTS ':ListsId:'...' )
   return 0
end
convert '*' to @fm in Params
EntryDateFrom = Params<1>
EntryDateThru = Params<2>
Custs         = Params<3>
Open          = Params<4>
Closed        = Params<5>

Stat = utility( 'CURSOR', 'H' )

WithStmt = 'SELECT ':TableName:' '
WthSwt = 0
Begin Case
   Case EntryDateFrom and EntryDateThru
      WthSwt = 1
      WithStmt :=  " WITH ENTRY_DATE FROM '": EntryDateFrom:"' TO '":EntryDateThru: "' "
      TtlLin2 = 'Entry Dates: From ':EntryDateFrom:' To ':EntryDateThru
   Case EntryDateFrom
      WthSwt = 1
      WithStmt := " WITH ENTRY_DATE GE '":EntryDateFrom:"' "
      TtlLin2 = 'Entry Dates: From ':EntryDateFrom:' To Latest'
   Case EntryDateThru
      WthSwt = 1
      WithStmt := " WITH ENTRY_DATE LE '":EntryDateThru:"' "
      TtlLin2 = 'Entry Dates: From Earliest To ':EntryDateThru
   Case 1
      TtlLin2 = 'Entry Dates: ALL'
End Case

If Custs then
   CustCnt = Count(@vm,Custs)
   If CustCnt > 20 Then 
      TtlLin3 = 'Customers: More Than 20 Selected'
   End Else
      TtlLin3 = Custs
      swap @vm with ", " in TtlLin3
      TtlLin3 = 'Customers: ':TtlLin3
   End      
   swap @vm with "' '" in Custs
   Custs = "'":Custs:"'"
   If WthSwt Then WithStmt := ' AND '
   WithStmt := ' WITH CUST_NO = ':Custs
   WthSwt = 1
end else
   TtlLin3 = 'Customers: ALL'
end

If Open then
   If WthSwt Then WithStmt := ' AND '
   WithStmt := ' WITH STATUS = "O" '
end
If Closed then
   If WthSwt Then WithStmt := ' AND '
   WithStmt := ' WITH STATUS = "C" '
end

rlist( WithStmt, target_savelist$, ListsId, '', '' )
activate_save_select( ListsId )

Script = SRptConfig<SlistScript$>

RptWdt = SRptConfig<Width$>

Title	= obj_Install('Get_Prop','Company'):' ':SRptConfig<Title$>
Margin	=  INT((RptWdt - LEN(Title))/2)
LMargin = Margin - 10		;* 10 equals length of the date
RMargin = Margin - 8		;* 8 equals length of 'Page....'
Title = OCONV(Date(),'D4/'):SPACE(LMargin):Title:SPACE(RMargin):"Page'PP''L'"

SWAP '~Title~' WITH Title IN Script

TitleLine2 = TtlLin2
TitleLine3 = TtlLin3
TitleLine4 = ''

IF TitleLine2 NE '' THEN
	Margin = INT((RptWdt - LEN(TitleLine2))/2)
	LMargin = Margin - 7	;* 7 equals length of time (12:15PM)
	RMargin = Margin
	TitleLine2 = OCONV(Time(),'MTH'):SPACE(LMargin):TitleLine2:SPACE(RMargin)
	SWAP '~SecondTitleLine~'  WITH TitleLine2 IN Script
END ELSE
	SWAP '~SecondTitleLine~' WITH '' IN Script
END	

IF TitleLine3 NE '' THEN
	Margin = INT((RptWdt - LEN(TitleLine3))/2)
	SWAP '~ThirdTitleLine~'  WITH "'L'":TitleLine3 IN Script
END ELSE
	SWAP '~ThirdTitleLine~' WITH '' IN Script
END

IF TitleLine4 NE '' THEN
	Margin = INT((RptWdt - LEN(TitleLine4))/2)
	SWAP '~FourthTitleLine~'  WITH "'L'":TitleLine4 IN Script
END ELSE
	SWAP '~FourthTitleLine~' WITH '' IN Script
END

Script := ' FOOTING "* Status  O = Open;  C = Closed" '

* Added after upgrade to OI4.13a to reset default printer in OIPI32 engine.
DefaultPrinter = ''
PrintCount     = PrintSetup(PRN_GET$,'',Printers,DefaultPrinter)
CONVERT ',' TO @FM IN DefaultPrinter
DefPrintPath   = DefaultPrinter<1>:@FM:DefaultPrinter<3>

Void = set_printer( 'INIT', '', '', .63:@fm:.63:@fm:.25:@fm:'', 0,'',DefPrintPath )
Void = Set_Printer('TERM')

call slist( Script )

Void = utility( 'CURSOR', 'A' )      
      
write '' on SysListsTable, ListsId else
    Void = msg( '', 'Unable to clear SYSLISTS ':ListsId:'...' )
    return 0
end
RETURN 0