Function Version_API(@API)
/***********************************************************************************************************************

    This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
    permission from SRP Computer Solutions, Inc.

    Name        :   Version_API

    Description :   API logic for the Version resource.

    Notes       :   All web APIs should include the API_SETUP insert. This will provide several useful variables:

                        HTTPMethod              - The HTTP Method (Verb) submitted by the client (e.g., GET, POST, etc.)
                        APIURL                  - The URL for the API entry point (e.g., api.mysite.com/v1).
                        FullEndpointURL         - The URL submitted by the client.
                        CurrentAPI              - The name of this stored procedure.    

    Parameters  :
        API             [in] -- Web API to process. Format is [APIPattern].[HTTPMethod]:
                                    - APIPattern must follow this structure <Resource>[.ID.[<Property>]]
                                    - HTTPMethod can be any valid HTTP method, e.g., GET, POST, PUT, DELETE, etc.
                                Examples:
                                    - Version.POST
                                    - Version.ID.PUT
                                    - Version.ID.firstName.GET
        Response       [out] -- Response to be sent back to the Controller (HTTP_MCP) or requesting procedure. Web API
                                services do not rely upon anything being returned in the response. This is what the
                                various services like SetResponseBody and SetResponseStatus services are for. A response
                                value is only helpful if the developers want to use it for debug purposes.

    History     :   (Date, Initials, Notes)
        11/19/18    dmb     Original programmer.
        05/28/19    dmb     [SRPFW-274] Replace all references to AddLinkRelationships with AddLinkRelations.
        01/23/20    dmb     [SRPFW-296] Add matching HEAD APIs for all GET APIs.

***********************************************************************************************************************/

#pragma precomp SRP_PreCompiler

$insert APP_INSERTS
$insert API_SETUP
$insert HTTP_INSERTS

GoToAPI else
    // The specific resource endpoint doesn't have a API handler yet.
    HTTP_Services('SetResponseStatus', 204, 'This is a valid endpoint but a web API handler has not yet been created.')
end

Return Response OR ''


////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Endpoint Handlers
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

API version.HEAD
API version.GET

    Version     = HTTP_Services('GetVersion')
    If Error_Services('NoError') then
        Swap CRLF$ with @FM in Version
        Properties  = 'version' : @FM : 'date' : @FM : 'time'
        Values      = Version<1> : @FM : Field(Version<2>, ' ', 1, 1) : @FM : Field(Version<2>, ' ', 2, 1)
        objResource = HTTP_Resource_Services('AddProperties', '', Properties, Values)
        Rels        = 'self' : @FM : 'apiEntryPoint'
        URLs        = FullEndpointURL : @FM : APIURL
        HTTP_Resource_Services('AddLinkRelations', objResource, Rels, URLs)

        If Error_Services('NoError') then
            // Serialize the object into a JSON string.
            jsonResource    = HTTP_Resource_Services('GetSerializedResource', objResource)
            // Set the response body with the JSON string and set the Content-Type response header.
            HTTP_Services('SetResponseBody', jsonResource, False$, 'application/hal+json')
        end else
            HTTP_Services('SetResponseError', '', '', 500, Error_Services('GetMessage'), FullEndpointURL)
        end
    end else
        HTTP_Services('SetResponseError', '', '', 500, Error_Services('GetMessage'), FullEndpointURL)
    end

end api