Function FISCAL_YR_Actions(Action, CalcColName, FSList, Handle, Name, FMC, Record, Status, OrigRecord, Param1, Param2, Param3, Param4, Param5, Param6, Param7, Param8, Param9, Param10)
/***********************************************************************************************************************

    This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
    permission from Infineon.

    Name        :   Fiscal_Yr_Actions

    Description :   Handles calculated columns and MFS calls for the current table.

    Notes       :   This function uses @ID, @RECORD, and @DICT to make sure {ColumnName} references work correctly.
                    If called from outside of a calculated column these will need to be set and restored.

    Parameters  :
        Action          [in] -- Name of the action to be taken
        CalcColName     [in] -- Name of the calculated column that needs to be processed. Normally this should only be
                                populated when the CalcField action is being used.
        FSList          [in] -- The list of MFSs and the BFS name for the current file or volume. This is an @SVM
                                delimited array, with the current MFS name as the first value in the array, and the BFS
                                name as the last value. Normally set by a calling MFS.
        Handle          [in] -- The file handle of the file or media map being accessed. Note, this does contain the
                                entire handle structure that the Basic+ Open statement would provide. Normally set by a
                                calling MFS.
        Name            [in] -- The name (key) of the record or file being accessed. Normally set by a calling MFS.
        FMC             [in] -- Various functions. Normally set by a calling MFS.
        Record          [in] -- The entire record (for record-oriented functions) or a newly-created handle (for
                                "get handle" functions). Normally set by a calling MFS.
        Status      [in/out] -- Indicator of the success or failure of an action. Normally set by the calling MFS but
                                for some actions can be set by the action handler to indicate failure.
        OrigRecord      [in] -- Original content of the record being processed by the current action. This is
                                automatically being assigned by the WRITE_RECORD and DELETE_RECORD actions within
                                BASE_MFS.
        Param1-10   [in/out] -- Additional request parameter holders
        ActionFlow     [out] -- Used to control the action chain (see the ACTION_SETUP insert for more information.)
                                Can also be used to return a special value, such as the results of the CalcField
                                method.

    History     :   (Date, Initials, Notes)
        10/03/24    djs     Original programmer.

***********************************************************************************************************************/

#pragma precomp SRP_PreCompiler

$Insert FILE.SYSTEM.EQUATES
$Insert ACTION_SETUP
$Insert APP_INSERTS
$Insert FISCAL_YR_EQUATES
$Insert SHIFT_CALENDAR_EQUATES

Declare function    LSL_Users_Services
Declare subroutine  Database_Services

If KeyID then GoSub Initialize_System_Variables

Begin Case

    Case Action _EQC 'CalculateColumn'      ;   GoSub CalculateColumn
    Case Action _EQC 'READ_RECORD_PRE'      ;   GoSub READ_RECORD_PRE
    Case Action _EQC 'READ_RECORD'          ;   GoSub READ_RECORD
    Case Action _EQC 'READONLY_RECORD_PRE'  ;   GoSub READONLY_RECORD_PRE
    Case Action _EQC 'READONLY_RECORD'      ;   GoSub READONLY_RECORD
    Case Action _EQC 'WRITE_RECORD_PRE'     ;   GoSub WRITE_RECORD_PRE
    Case Action _EQC 'WRITE_RECORD'         ;   GoSub WRITE_RECORD
    Case Action _EQC 'DELETE_RECORD_PRE'    ;   GoSub DELETE_RECORD_PRE
    Case Action _EQC 'DELETE_RECORD'        ;   GoSub DELETE_RECORD
    Case Otherwise$                         ;   Status = 'Invalid Action'

End Case

If KeyID then GoSub Restore_System_Variables

If Assigned(ActionFlow) else ActionFlow = ACTION_CONTINUE$

Return ActionFlow


////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Calculated Columns 
//
// The typical structure of a calculated column will look like this:
//
// Declare function Database_Services
//
// @ANS = Database_Services('CalculateColumn')
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

CalculateColumn:

    // Make sure the ActionFlow return variable is cleared in case nothing is calculated.
    ActionFlow = ''

return


// ----- MFS calls -----------------------------------------------------------------------------------------------------

READ_RECORD_PRE:
    // In order to stop a record from being read in this action these lines of code must be used:
    //
    //    OrigFileError   = 100 : @FM : KeyID
    //    Status          = 0
    //    Record          = ''
    //    ActionFlow      = ACTION_STOP$
return

READ_RECORD:

    // In order to stop a record from being read in this action these lines of code must be used:
    //
    //    OrigFileError   = 100 : @FM : KeyID
    //    Status          = 0
    //    Record          = ''
    
return

READONLY_RECORD_PRE:
    // In order to stop a record from being read in this action these lines of code must be used:
    //
    //    OrigFileError   = 100 : @FM : KeyID
    //    Status          = 0
    //    Record          = ''
    //    ActionFlow      = ACTION_STOP$
return

READONLY_RECORD:
    // In order to stop a record from being read in this action these lines of code must be used:
    //
    //    OrigFileError   = 100 : @FM : KeyID
    //    Status          = 0
    //    Record          = ''
return

WRITE_RECORD_PRE:
return

WRITE_RECORD:

	If OrigRecord NE Record then 
		FiscalYear     = Name
		FiscalWeeks    = {WK_NO}
		FiscalStartDts = {WK_START_DT}
		FiscalEndDts   = {WK_END_DT}
		FiscalMonthNos = {WK_MONTH_NO}
		FiscalQtrs     = {WK_QTR_NO}
		
		For each FiscalWeek in FiscalWeeks using @VM setting vPos
			
			FiscalStartDt = FiscalStartDts<0, vPos>
			FiscalEndDt   = FiscalEndDts<0, vPos>
			If FiscalMonthNos<0, vPos> NE '' then 
				FiscalMonthNo = FiscalMonthNos<0, vPos>
			end
			If FiscalQtrs<0, vPos> NE '' then
				FiscalQtr = FiscalQtrs<0, vPos>
			end
			
			For InternalDate = FiscalStartDt to FiscalEndDt Step 1
				
				FirstShiftRec  = ''
				SecondShiftRec = ''
				
				OutDate              = OConv(InternalDate, 'D4/')
				OutDatePlusOne       = OConv(InternalDate + 1, 'D4/')
				FirstShiftStartTime  = '06:00:00AM'
				FirstShiftStartDtm   = OutDate : ' ' : FirstShiftStartTime
				FirstShift           = LSL_Users_Services('GetShiftByDate', FirstShiftStartDtm)
				FirstShiftEndDtm     = OutDate : ' 5:59:59PM'
				SecondShiftStartTime = '06:00:00PM'
				SecondShiftStartDtm  = OutDate : ' ' : SecondShiftStartTime
				SecondShift          = LSL_Users_Services('GetShiftByDate', SecondShiftStartDtm)
				
				SecondShiftEndDtm    = OutDatePlusOne : ' 05:59:59AM'
				
				ShiftDate  = OConv(InternalDate, 'DH')
				ShiftMonth = Field(ShiftDate, ' ', 1, 1)
				ShiftDay   = Field(ShiftDate, ' ', 1, 2)
				Convert ' ' to '' in ShiftDay
				ShiftYear  = Field(ShiftDate, ' ', 3, 1)
				
				FirstShiftKey  = ShiftDay : '*' : FiscalYear : '*' : FirstShift
				SecondShiftKey = ShiftDay : '*' : FiscalYear : '*' : SecondShift
				
				FirstShiftRec<SHIFT_CALENDAR.START_DTM$>      = IConv(FirstShiftStartDtm, 'DT')
				FirstShiftRec<SHIFT_CALENDAR.END_DTM$>        = IConv(FirstShiftEndDtm, 'DT')
				FirstShiftRec<SHIFT_CALENDAR.FISCAL_WEEK$>    = 'WW':FiscalWeek
				FirstShiftRec<SHIFT_CALENDAR.FISCAL_MONTH$>   = FiscalMonthNo
				FirstShiftRec<SHIFT_CALENDAR.FISCAL_QUARTER$> = 'Q':FiscalQtr 
				
				Database_Services('WriteDataRow', 'SHIFT_CALENDAR', FirstShiftKey, FirstShiftRec)
				
				SecondShiftRec<SHIFT_CALENDAR.START_DTM$>      = IConv(SecondShiftStartDtm, 'DT')
				SecondShiftRec<SHIFT_CALENDAR.END_DTM$>        = IConv(SecondShiftEndDtm, 'DT')
				SecondShiftRec<SHIFT_CALENDAR.FISCAL_WEEK$>    = 'WW':FiscalWeek
				SecondShiftRec<SHIFT_CALENDAR.FISCAL_MONTH$>   = FiscalMonthNo
				SecondShiftRec<SHIFT_CALENDAR.FISCAL_QUARTER$> = 'Q':FiscalQtr 
				
				Database_Services('WriteDataRow', 'SHIFT_CALENDAR', SecondShiftKey, SecondShiftRec)
				
			Next InternalDate
			
		Next FiscalWeek
	end
	
return

DELETE_RECORD_PRE:
return

DELETE_RECORD:
return



////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Internal GoSubs
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

ClearCursors:
    For counter = 0 to 8
        ClearSelect counter
    Next counter
return


Initialize_System_Variables:

    // Save these for restoration later
    SaveDict        = @DICT
    SaveID          = @ID
    SaveRecord      = @RECORD
    OrigFileError   = @FILE.ERROR

    // Now make sure @DICT, ID, and @RECORD are populated
    CurrentDictName = ''
    If @DICT then
        DictHandle = @DICT<1, 2>
        Locate DictHandle in @TABLES(5) Using @FM Setting fPos then
            CurrentDictName = Field(@TABLES(0), @FM, fPos, 1)
        end
    end

    If CurrentDictName NE DictName then
         Open DictName to @DICT else Status = 'Unable to initialize @DICT'
    end    

    @ID = KeyID
    If Record else
        // Record might not have been passed in. Read the record from the database table just to make sure.
        @FILE.ERROR     = ''
        Open TableName to hTable then
            FullFSList  = hTable[1, 'F' : @VM]
            BFS         = FullFSList[-1, 'B' : @SVM]
            LastHandle  = hTable[-1, 'B' : \0D\]
            FileHandle  = \0D\ : LastHandle[1, @VM]

            Call @BFS(READO.RECORD, BFS, FileHandle, KeyID, FMC, Record, ReadOStatus)
        end
    end
    @RECORD = Record

return


Restore_System_Variables:

    Transfer SaveDict   to @DICT
    Transfer SaveID     to @ID
    Transfer SaveRecord to @RECORD
    @FILE.ERROR = OrigFileError

return