phares3757/open-insight
3
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

added LSL2 stored procedures

Browse Source
This commit is contained in:
Infineon\StieberD
2024-03-25 14:46:21 -07:00
parent 09f1a66046
commit c667dd56eb
1655 changed files with 527967 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

391
LSL2/STPROC/SCHEDULER_ACTIONS_MODIFY_EVENTS.txt Normal file
View File

@ -0,0 +1,391 @@
Function Scheduler_Actions_Modify_Events(CtrlEntId, Event, Param1, Param2, Param3, Param4, Param5, Param6, Param7, Param8, Param9, Param10, Param11, Param12, Param13, Param14, Param15)
/***********************************************************************************************************************
This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
permission from Infineon.
Name : Scheduler_Actions_Modify_Events
Description : This function acts as a commuter module for all events related to this window.
Notes : Commuter Modules are automatically called from the Promoted_Events function which is called by the
application-specific promoted event handler. This makes it possible to add QuickEvents that need to
execute Basic+ logic without having use the Form Designer to make the association, although this is
limited to the events which are currently promoted.
If the form needs to call the commuter module directly then the QuickEvent parameters should be
formatted like this:
'@SELF','@EVENT',['@PARAM1','@PARAMx']
Parameters :
CtrlEntId [in] -- The fully qualified name of the control calling the promoted event
Event [in] -- The event being executed. See the Notes section regarding "PRE" events
Param1-15 [in] -- Additional event parameter holders
EventFlow [out] -- Set to 1 or 0 so the calling event knows whether or not to chain forward. See comments in
EVENT_SETUP insert
History : (Date, Initials, Notes)
02/19/21 djs Created initial commuter module.
***********************************************************************************************************************/
#pragma precomp SRP_PreCompiler
#Window SCHEDULER_ACTIONS_MODIFY
$insert APP_INSERTS
$insert EVENT_SETUP
$insert MSG_EQUATES
$insert SCHED_DET_NG_EQUATES
$insert WO_LOG_EQUATES
$insert WO_SCHEDULE_NG_EQUATES
$insert REACTOR_EQUATES
Equ OI_DISABLED_GREY$ TO 239 + (239*256) + (239*65536)
WorkOrderCtrls = 'OLE_DIV_WORK_ORDER_DETAILS,WO_NO_LABEL,WO_NO,EPI_PART_LABEL,EPI_PART,DESCRIPTION_LABEL,DESCRIPTION,CUSTOMER_NAME_LABEL,CUSTOMER_NAME,'
WorkOrderCtrls := 'TOTAL_WAFERS_LABEL,TOTAL_WAFERS,TOTAL_REMAINING_LABEL,TOTAL_REMAINING,PERCENT_COMPLETE_LABEL,PERCENT_COMPLETE'
DateRangeCtrls = 'SCHEDULE_START_DTM_LABEL,SCHEDULE_START_DTM,SCHEDULE_END_DTM_LABEL,SCHEDULE_END_DTM,DAYS_LABEL,DAYS'
Declare function SRP_Array, Schedule_Services_Dev, Database_Services, Work_Order_Services, SRP_Math
Declare function Epi_Part_Services, Datetime
Declare subroutine obj_Appwindow, Center_Window, Schedule_Services_Dev, Form_Services, SRP_Show_Window
Declare subroutine Form_Services
SubclassInfo = Form_Services('FindSubclassControl')
Subclass = SubclassInfo<1>
// Update the arguments so that the OpenInsight OLE event will treate the ActiveX event as a native event handler.
If Event EQ 'OLE' then
Transfer Event to OIEvent
Transfer Param1 to Event
Transfer Param2 to Param1
Transfer Param3 to Param2
Transfer Param4 to Param3
Transfer Param5 to Param4
Transfer Param6 to Param5
Transfer Param7 to Param6
Transfer Param8 to Param7
end
Type = Get_Property(CtrlEntId, 'TYPE')
If Type EQ 'RADIOBUTTON' then
Convert ' ' to '_' in CtrlEntID
end
GoToEvent Event for CtrlEntID
Return EventFlow else EVENT_CONTINUE$
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Events
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
Event WINDOW.CREATE(CreateParam)
SchedDetNGKey = CreateParam<3>
Set_Property(@Window, '@SCHEDULE_KEY_ID', SchedDetNGKey)
GoSub PopulateControls
Set_Property(@Window : '.DESCRIPTION', 'NEXT', @Window : '.NEW_QTY')
SRP_Show_Window(@Window, '', 'C', 'C', 1, '', False$, False$)
end event
Event WINDOW.CLOSE(CancelFlag)
end event
Event SAVE_BUTTON.CLICK()
GoSub UpdateWorkOrderDetails
ResponseData = ''
ReactorNo = Get_Property(@Window : '.REACTOR_NO', 'TEXT')
WorkOrder = Get_Property(@Window : '.WO_NO', 'TEXT')
StartDTM = Get_Property(@Window : '.SCHEDULE_START_DTM', 'INVALUE')
EndDTM = Get_Property(@Window : '.SCHEDULE_END_DTM', 'INVALUE')
Description = Get_Property(@Window : '.DESCRIPTION', 'INVALUE')
NewQty = Get_Property(@Window : '.NEW_QTY', 'TEXT')
If NewQty EQ '' then NewQty = Get_Property(@Window:'.SCHEDULE_WAFERS', 'INVALUE')
ResponseData = ReactorNo : @FM : WorkOrder : @FM : StartDTM : @FM : EndDTM : @FM : Description : @FM : NewQty
End_Dialog(@Window, ResponseData)
end event
Event CLOSE_BUTTON.CLICK()
End_Dialog(@Window, '')
end event
Event OLE_SUBCLASS.OnOptionClick(CtrlId)
Send_Event(CtrlId, 'OPTIONS')
end event
Event OLE_SUBCLASS.OnComboClick(CtrlId)
Send_Event(CtrlId, 'LOSTFOCUS')
end event
Event NEW_QTY.CHAR(VirtCode, ScanCode, CtrlKey, ShiftKey, AltKey)
Form_Services('CloseControlMessage', CtrlEntId)
GoSub EnableSaveButton
end event
Event NEW_QTY.LOSTFOCUS(Flag, FocusID)
ValidQty = False$
NewQty = Get_Property(CtrlEntID, 'TEXT')
MinQty = Get_Property(@Window, '@MIN_QTY')
MaxQty = Get_Property(@Window, '@MAX_QTY')
Begin Case
Case NewQty EQ ''
Null
Case NewQty LE 0
Set_Property(CtrlEntID, 'FOCUS', True$)
Set_Property(CtrlEntID, 'SELECTION', 1 : @FM : 999)
Message = 'New quantity must greater than zero.'
Form_Services('DisplayControlMessage', Message, 'Invalid Quantity', CtrlEndID, 'VALIDATION', 'RGB(229,20,0)')
Case NewQty LT MinQty
Set_Property(CtrlEntID, 'FOCUS', True$)
Set_Property(CtrlEntID, 'SELECTION', 1 : @FM : 999)
Message = 'New quantity is below already processed quantity.'
Form_Services('DisplayControlMessage', Message, 'Invalid Quantity', CtrlEndID, 'VALIDATION', 'RGB(229,20,0)')
Case NewQty GT MaxQty
Set_Property(CtrlEntID, 'FOCUS', True$)
Set_Property(CtrlEntID, 'SELECTION', 1 : @FM : 999)
Message = 'New quantity exceeds the available quantity.'
Form_Services('DisplayControlMessage', Message, 'Invalid Quantity', CtrlEndID, 'VALIDATION', 'RGB(229,20,0)')
Case Otherwise$
ValidQty = True$
End Case
If ValidQty then GoSub UpdateWorkOrderDetails
end event
Event DESCRIPTION.CHAR(VirtCode, ScanCode, CtrlKey, ShiftKey, AltKey)
GoSub EnableSaveButton
end event
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Internal GoSubs
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
SelectAll:
Set_Property(CtrlEntId, 'SELECTION', 1 : @FM : 999)
return
* UpdateScheduleDetails:
*
* ScheduleDetail = Schedule_Services_Dev('GetScheduleDetail', ScheduleKeyID)
* Set_Property(@Window, '@ORIG_SCHEDULEDETAIL', ScheduleDetail)
* Desc = ScheduleDetail<SCHED_DET_NG.DESC$>
* Set_Property(@Window : '.DESCRIPTION', 'TEXT', Desc)
* Set_Property(@Window, '@ORIG_DESC', Desc)
*
* return
UpdateCustomerName:
WoNo = Get_Property(@Window : '.WO_NO', 'TEXT')
If WoNo NE '' then
WorkOrderDetail = Work_Order_Services('GetWorkOrderLogDetail', WONo)
CustNo = WorkOrderDetail<WO_LOG_CUST_NO$>
CompanyRow = Database_Services('ReadDataRow', 'COMPANY', CustNo)
CustName = CompanyRow<42>
end else
CustName = ''
end
Set_Property(@Window : '.CUSTOMER_NAME', 'TEXT', CustName)
return
UpdateReactorDetails:
ReactorNo = Get_Property(@Window : '.REACTOR_NO', 'TEXT')
If Index(ReactorNo, '/', 1) then
// EpiPro reactors formatted as such, "40/42". We must truncate the reactor number to the first reactor.
ReactorNo = Field(ReactorNo, '/', 1, 1)
Set_Property(@Window : '.REACTOR_NO', 'TEXT', ReactorNo)
end
ReactorDetails = Schedule_Services_Dev('GetReactorDetails', ReactorNo)
ReactorType = ReactorDetails<REACTOR_REACT_TYPE$>
Begin Case
Case ReactorType _EQC 'EPP' ; ReactorType = 'EpiPro'
Case ReactorType _EQC 'GAN' ; ReactorType = 'GaN'
End Case
Set_Property(@Window : '.REACTOR_TYPE', 'TEXT', ReactorType)
Set_Property(@Window : '.REACTOR_SIZE', 'TEXT', ReactorDetails<REACTOR_SUSC_POCKET_SIZE$>)
FutureEvents = Schedule_Services_Dev('GetScheduleEvents', Date() + 1, '', ReactorNo, '', False$)
Set_Property(@Window, '@FUTURE_EVENTS', FutureEvents)
return
UpdateWorkOrderDetails:
SchedDetNGKey = Get_Property(@Window, '@SCHEDULE_KEY_ID')
If SchedDetNGKey NE '' then
CurrDTM = Datetime()
SchedDetNGRec = Database_Services('ReadDataRow', 'SCHED_DET_NG', SchedDetNGKey)
WorkOrder = Get_Property(@Window : '.WO_NO', 'TEXT')
ReactNo = Get_Property(@Window : '.REACTOR_NO', 'TEXT')
WorkOrderDetail = Work_Order_Services('GetWorkOrderLogDetail', WorkOrder)
EpiPart = WorkOrderDetail<WO_LOG_EPI_PART_NO$>
TotalWafers = WorkOrderDetail<WO_LOG_WO_QTY$>
RemainingToProcess = Work_Order_Services('GetUnprocessedWafers', WorkOrder)
RemainingToSchedule = Schedule_Services_Dev('GetUnscheduledWfrQty', WorkOrder)
If TotalWafers GT 0 then
Complete = ( (TotalWafers - RemainingToProcess) / TotalWafers) * 100
end else
Complete = 0
end
ReactorType = Get_Property(@Window : '.REACTOR_TYPE', 'TEXT')
MinutesPerWaferAdjusted = Epi_Part_Services('GetAdjustedWafersPerDayScheduler', EpiPart, ReactorType)
ScheduledWfrQty = Schedule_Services_Dev('GetScheduledWfrQty', WorkOrder)
AvailableWfrQty = RemainingToSchedule
CurrEventQty = Get_Property(@Window:'.SCHEDULE_WAFERS', 'TEXT')
EventProcCass = SchedDetNGRec<SCHED_DET_NG.PROCESSED_CASS$>
EventUnprocCass = SchedDetNGRec<SCHED_DET_NG.UNPROCESSED_CASS$>
// Check for currently loaded cassettes
LoadedCassettes = 0
EpiPro = (Xlate('WO_LOG', WorkOrder, 'REACT_TYPE', 'X') EQ 'EPP')
For each CassNo in EventUnprocCass using @VM setting vPos
If EpiPro then
// Check if RDS in slot 25 is loaded into a reactor
WMIKey = WorkOrder:'*1*':CassNo
WMIRDSNos = Xlate('WM_IN', WMIKey, 'RDS_NO', 'X')
LastSlotRDS = WMIRDSNos<0, 25>
If LastSlotRDS NE '' then
DateIn = Xlate('RDS', LastSlotRDS, 'DATE_IN', 'X')
DateOut = Xlate('RDS', LastSlotRDS, 'DATE_OUT', 'X')
If ( (DateIn NE '') and (DateOut EQ '') ) then
// Cassette is loaded into a reactor, so this cassette cannot be removed from the event.
LoadedCassettes += 1
end
end
end else
// Check if RDS is loaded into a reactor
WOMatKey = WorkOrder:'*':CassNo
RDSNo = Xlate('WO_MAT', WOMatKey, 'RDS_NO', 'X')
If RDSNo NE '' then
DateIn = Xlate('RDS', RDSNo, 'DATE_IN', 'X')
DateOut = Xlate('RDS', RDSNo, 'DATE_OUT', 'X')
If ( (DateIn NE '') and (DateOut EQ '') ) then
// Cassette is loaded into a reactor, so this cassette cannot be removed from the event.
LoadedCassettes += 1
end
end
end
Next CassNo
ProcessedWfrQty = (DCount(EventProcCass, @VM) * 25)
UnprocessedWfrQty = Schedule_Services_Dev('GetEventRemainingWfrs', SchedDetNGKey)
NewEventQty = Get_Property(@Window:'.NEW_QTY', 'TEXT')
StartDTM = SchedDetNGRec<SCHED_DET_NG.START_DTM$>
If ( (NewEventQty NE CurrEventQty) and (NewEventQty NE '') ) then
DurationEstimate = Schedule_Services_Dev('GetEventDuration', WorkOrder, (NewEventQty - ProcessedWfrQty))
EndDTM = CurrDTM + DurationEstimate
end else
EndDTM = SchedDetNGRec<SCHED_DET_NG.STOP_DTM$>
end
TotalRunTime = EndDTM - StartDTM
CurrEventQty = SchedDetNGRec<SCHED_DET_NG.EVENT_TOTAL_WFRS$>
NewEventMin = CurrEventQty - UnprocessedWfrQty
Set_Property(@Window, '@MIN_QTY', NewEventMin)
NewEventMax = RemainingToSchedule + CurrEventQty
Set_Property(@Window, '@MAX_QTY', NewEventMax)
NewQtyLabel = 'New Qty (':NewEventMin:' - ':NewEventMax:'):'
If MinutesPerWaferAdjusted EQ '' then
Msg(@Window, 'Warning: ' : EpiPart : ' appears to be missing minutes per wafer values for ' : ReactorType)
end
end
If (SchedDetNGKey NE '') then
Set_Property(@Window : '.EPI_PART', 'TEXT', EpiPart)
Set_Property(@Window : '.TOTAL_WAFERS', 'TEXT', TotalWafers)
Set_Property(@Window : '.TOTAL_REMAINING', 'TEXT', RemainingToProcess)
Set_Property(@Window : '.PERCENT_COMPLETE', 'TEXT', Oconv(Complete, 'MD0[ %]S'))
Set_Property(@Window : '.SCHEDULE_END_DTM', 'INVALUE', EndDTM)
RunTimeRounded = SRP_Math('ROUND', TotalRunTime, 1)
Set_Property(@Window : '.DAYS', 'DEFPROP', RunTimeRounded)
Set_Property(@Window : '.AVAILABLE_QTY', 'TEXT', AvailableWfrQty)
Set_Property(@Window : '.OPTIONS_NEW_QTY', 'TEXT', NewQtyLabel)
end else
Error_Services('DisplayError')
Set_Property(@Window : '.EPI_PART', 'TEXT', '')
Set_Property(@Window : '.TOTAL_WAFERS', 'TEXT', '')
Set_Property(@Window : '.TOTAL_REMAINING', 'TEXT', '')
Set_Property(@Window : '.SCHEDULE_WAFERS', 'TEXT', '')
Set_Property(@Window : '.PERCENT_COMPLETE', 'TEXT', '')
Set_Property(@Window : '.SCHEDULE_END_DTM', 'INVALUE', '')
Set_Property(@Window : '.DAYS', 'DEFPROP', '')
end
GoSub EnableSaveButton
return
PopulateControls:
Set_Property(@Window, 'TEXT', 'Scheduler Actions - Modify Work Order Event')
Set_Property(@Window : '.REACTOR_NO', 'NEXT', @Window : '.SCHEDULE_START_DTM')
Set_Property(@Window : '.DESCRIPTION', 'NEXT', @Window : '.REACTOR_NO')
SchedDetNGKey = Get_Property(@Window, '@SCHEDULE_KEY_ID')
SchedDetRec = Schedule_Services_Dev('GetScheduleDetail', SchedDetNGKey)
WONo = SchedDetRec<SCHED_DET_NG.WO_NO$>
ReactorNo = SchedDetRec<SCHED_DET_NG.REACT_NO$>
StartDTM = SchedDetRec<SCHED_DET_NG.START_DTM$>
StopDTM = SchedDetRec<SCHED_DET_NG.STOP_DTM$>
EventWfrs = SchedDetRec<SCHED_DET_NG.EVENT_TOTAL_WFRS$>
Desc = SchedDetRec<SCHED_DET_NG.DESC$>
Set_Property(@Window : '.WO_NO', 'TEXT', WONo)
Set_Property(@Window : '.REACTOR_NO', 'TEXT', ReactorNo)
Set_Property(@Window : '.SCHEDULE_START_DTM', 'INVALUE', StartDTM)
Set_Property(@Window : '.SCHEDULE_END_DTM', 'INVALUE', StopDTM)
Set_Property(@Window : '.SCHEDULE_WAFERS', 'INVALUE', EventWfrs)
Set_Property(@Window : '.DESCRIPTION', 'INVALUE', Desc)
* GoSub UpdateScheduleDetails
GoSub UpdateReactorDetails
GoSub UpdateCustomerName
GoSub UpdateWorkOrderDetails
Set_Property(@Window : '.REACTOR_NO', 'FOCUS', True$)
return
EnableSaveButton:
OrigDesc = Get_Property(@Window, '@ORIG_DESC')
NewDesc = Get_Property(@Window : '.DESCRIPTION', 'TEXT')
CurrQty = Get_Property(@Window : '.SCHEDULE_WAFERS', 'TEXT')
NewQty = Get_Property(@Window : '.NEW_QTY', 'TEXT')
MinQty = Get_Property(@Window, '@MIN_QTY', 'TEXT')
MaxQty = Get_Property(@Window, '@MAX_QTY', 'TEXT')
DescChange = (NewDesc NE OrigDesc)
QtyChange = ( (NewQty NE '') and (NewQty NE CurrQty) and (NewQty GT 0) and (NewQty LE MaxQty) and (NewQty GE MinQty) )
ButtonEnabled = (DescChange or QtyChange)
Set_Property(@Window : '.SAVE_BUTTON', 'ENABLED', ButtonEnabled)
return