added LSL2 stored procedures

LSL2/STPROC/NDW_USER_SESSIONS_EVENTS.txt

@@ -0,0 +1,130 @@
+Function NDW_User_Sessions_Events(CtrlEntId, Event, @PARAMS)
+/***********************************************************************************************************************
+
+    This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
+    permission from Infineon.
+
+    Name        :   NDW_User_Sessions_Events
+
+    Description :   This function acts as a commuter module for all events related to this window.
+
+    Notes       :   Commuter Modules are automatically called from the Promoted_Events function which is called by the
+                    application-specific promoted event handler. This makes it possible to add QuickEvents that need to
+                    execute Basic+ logic without having use the Form Designer to make the association, although this is
+                    limited to the events which are currently promoted.
+
+                    If the form needs to call the commuter module directly then the QuickEvent parameters should be
+                    formatted like this:
+
+                        '@SELF','@EVENT',['@PARAM1','@PARAMx']
+
+    Parameters  :
+        CtrlEntId   [in] -- The fully qualified name of the control calling the promoted event
+        Event       [in] -- The event being executed. See the Notes section regarding "PRE" events
+        Param1-15   [in] -- Additional event parameter holders
+        EventFlow  [out] -- Set to 1 or 0 so the calling event knows whether or not to chain forward. See comments in
+                            EVENT_SETUP insert
+
+    History     :   (Date, Initials, Notes)
+        05/29/18    dmb     Created initial commuter module.
+
+***********************************************************************************************************************/
+
+#pragma precomp SRP_PreCompiler
+#Window NDW_USER_SESSIONS
+
+$insert APP_INSERTS
+$insert EVENT_SETUP
+$insert MSG_EQUATES
+
+Declare subroutine  SRP_Show_Window, Placedialog, Messaging_Services
+Declare function    Database_Services, Messaging_Services, GetCurrentProcessId
+
+SubclassInfo    = Form_Services('FindSubclassControl')
+Subclass        = SubclassInfo<1>
+
+// Update the arguments so that the OpenInsight OLE event will treate the ActiveX event as a native event handler.
+If Event EQ 'OLE' then
+    Transfer Event to OIEvent
+    Transfer Param1 to Event
+    Transfer Param2 to Param1
+    Transfer Param3 to Param2
+*    Transfer Param4 to Param3
+*    Transfer Param5 to Param4
+*    Transfer Param6 to Param5
+*    Transfer Param7 to Param6
+*    Transfer Param8 to Param7
+end
+
+GoToEvent Event for CtrlEntID
+
+Return EventFlow else EVENT_CONTINUE$
+
+
+////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
+// Events
+////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
+
+Event WINDOW.CREATE(CreateParam)
+
+    GoSub Setup_OLE_Controls
+
+    Set_Property(@Window : '.PUB_CLOSE', 'NEXT', @Window : '.EDT_USER_SESSIONS')
+
+    SRP_Show_Window(@Window, 'SYSTEM', 'C', 'C', 1, '', False$, False$)
+    Placedialog(-2, -2)
+
+    Post_Event(@Window : '.PUB_REFRESH', 'CLICK')
+
+end event
+
+
+Event WINDOW.OMNIEVENT(Message, Param1, Param2, Param3, Param4)
+
+    Begin Case
+        Case Message _EQC 'GetLoggedInUsers'
+            Transfer Param1 to SessionInfo
+            Station     = SessionInfo<1, 2>
+            OIUserName  = SessionInfo<2, 2>
+            SSOUserName = SessionInfo<3, 2>
+            ProcessID   = SessionInfo<4, 2>
+            Send_Message(@Window : '.EDT_USER_SESSIONS', 'INSERT', -1, Station : @VM : OIUserName : @VM : SSOUserName : @VM : ProcessID)
+
+    End Case
+
+end event
+
+
+Event PUB_REFRESH.CLICK()
+
+    Set_Property(@Window : '.EDT_USER_SESSIONS', 'ARRAY', '')
+    Messaging_Services('SendMessage', 'GetLoggedInUsers', 'Request', '', 'All', '', 'EventHandler', @Window : ',OMNIEVENT,@MESSAGE,@ARGUMENTS')
+
+end event
+
+
+Event PUB_SEND_MESSAGE.CLICK()
+
+    SessionInfo = Get_Property(@Window : '.EDT_USER_SESSIONS', 'ROWDATA')
+    If SessionInfo NE '' then
+        Message     = Get_Property(@Window : '.EDL_MESSAGE', 'TEXT')
+        If Message NE '' then
+            Messaging_Services('SendMessage', 'SetPopupMessage', 'Request', '', SessionInfo<1>, Message)
+        end
+    end
+
+end event
+
+
+////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
+// Internal GoSubs
+////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
+
+Setup_OLE_Controls:
+
+    Qualify     = ''
+    Qualify<1>  = 1
+    Qualify<4>  = 0
+
+return
+