Initial addition for Test Wafer Tracking Phase 2

Includes services and functions to create new
test wafer lot. Tables included outside of git push
New Tables:
1. LOT
2. LOT_EVENT
3. LOT_OPERATION
4. PRODUCT_OPERATION
5. OPERATION
6. Added PRODUCT_OPERATIONS field in TEST_WAFER_PROD table.
All relational indexes and btree indexes.

LSL2/STPROC/TESTWAFERPROD_API.txt

@@ -0,0 +1,134 @@
+Function Testwaferprod_API(@API)
+/***********************************************************************************************************************
+
+    This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
+    permission from SRP Computer Solutions, Inc.
+
+    Name        :   Testwaferprod_API
+
+    Description :   API logic for the Testwaferprod resource.
+
+    Notes       :   All web APIs should include the API_SETUP insert. This will provide several useful variables:
+
+                        HTTPMethod              - The HTTP Method (Verb) submitted by the client (e.g., GET, POST, etc.)
+                        APIURL                  - The URL for the API entry point (e.g., api.mysite.com/v1).
+                        FullEndpointURL         - The URL submitted by the client, including query params.
+                        FullEndpointURLNoQuery  - The URL submitted by the client, excluding query params.
+                        EndpointSegment         - The URL endpoint segment.
+                        ParentURL               - The URL path preceeding the current endpoint.
+                        CurrentAPI              - The name of this stored procedure.
+
+    Parameters  :
+        API             [in] -- Web API to process. Format is [APIPattern].[HTTPMethod]:
+                                    - APIPattern must follow this structure Testwaferprod[.ID.[<Property>]]
+                                    - HTTPMethod can be any valid HTTP method, e.g., GET, POST, PUT, DELETE, etc.
+                                Examples:
+                                    - Testwaferprod.POST
+                                    - Testwaferprod.ID.PUT
+                                    - Testwaferprod.ID.firstName.GET
+        Response       [out] -- Response to be sent back to the Controller (HTTP_MCP) or requesting procedure. Web API
+                                services do not rely upon anything being returned in the response. This is what the
+                                various services like SetResponseBody and SetResponseStatus services are for. A response
+                                value is only helpful if the developers want to use it for debug purposes.
+
+    History     :   (Date, Initials, Notes)
+        10/23/24    xxx     Original programmer.
+
+***********************************************************************************************************************/
+
+#pragma precomp SRP_PreCompiler
+
+Declare function Test_Wafer_Prod_Services, OI_WIZARD_SERVICES
+
+$insert APP_INSERTS
+$insert API_SETUP
+$insert HTTP_INSERTS
+$Insert LOGICAL
+
+GoToAPI else
+    // The specific resource endpoint doesn't have a API handler yet.
+    HTTP_Services('SetResponseStatus', 204, 'This is a valid endpoint but a web API handler has not yet been created.')
+end
+
+Return Response OR ''
+
+
+////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
+// Endpoint Handlers
+////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
+
+
+API testwaferprod.HEAD
+API testwaferprod.GET
+
+    OIWizardID = ''
+    Cookies    = HTTP_Services('GetHTTPCookie')
+    For each Cookie in Cookies using ';'
+        Key = Field(Cookie, '=', 1)
+        If Key EQ 'sessionID' then
+            OIWizardID = Field(Cookie, '=', 2)
+        end
+    Next Cookie
+    
+    ValidSession = OI_Wizard_Services('ValidateSession', OIWizardID)
+    If ValidSession then
+        //Send back list of printers
+        
+        StatusCode = 201
+        Message    = 'Success'
+        GoSub CreateHALCollection
+    end else
+        HTTP_Services('SetResponseStatus', 401, 'Invalid session. Reauthentication required.')
+    end
+
+end api
+
+//----------------------------------------------------------------------------------------------------------------------
+// CreateHALCollection
+//
+// Creates a HAL+JSON object based on OpenInsight data row representations.
+//----------------------------------------------------------------------------------------------------------------------
+CreateHALCollection:
+    
+    JSONCollection    = ''
+    Abort             = False$
+    TestWaferProdList = Test_Wafer_Prod_Services('GetAllTestWaferProdIDs', True$)
+    hJSONCollection   = ''
+    If SRP_JSON(hJSONCollection, 'New', 'Object') then
+    	hTestWaferProdIdArray = ''
+        If SRP_JSON(hTestWaferProdIdArray, 'New', 'Array') then
+            For each TWProdId in TestWaferProdList using @FM setting fPos
+                ReactorJSON = Test_Wafer_Prod_Services('ConvertRecordToJSON', TWProdId)
+                If Error_Services('NoError') then
+                	hTWProd = ''
+                    If (SRP_JSON(hTWProd, 'Parse', ReactorJSON) EQ '') then
+                        SRP_JSON(hTestWaferProdIdArray, 'Add', hTWProd)
+                        SRP_JSON(hTWProd, 'Release')
+                    end
+                end else
+                    Abort   = True$
+                end
+            Until Abort
+            Next TWProdId
+            If Abort EQ False$ then
+                SRP_JSON(hJSONCollection, 'Set', 'TestWaferProdIds', hTestWaferProdIdArray)
+            end
+            SRP_JSON(hTestWaferProdIdArray, 'Release')
+        end
+        JSONCollection = SRP_JSON(hJSONCollection, 'Stringify', 'Styled')
+        SRP_JSON(hJSONCollection, 'Release')
+    end
+    If Error_Services('NoError') then
+        HTTP_Services('SetResponseHeaderField', 'Content-Location', FullEndpointURL)
+        HTTP_Services('SetResponseBody', JSONCollection, False$, 'application/hal+json')
+        If Assigned(Message) then
+            HTTP_Services('SetResponseStatus', StatusCode, Message)
+        end else
+            HTTP_Services('SetResponseStatus', StatusCode)
+        end
+    end else
+        Message = Error_Services('GetMessage')          
+        HTTP_Services('SetResponseStatus', 500, 'Error in the ' : CurrentAPI : ' API. Message: ': Message)
+    end
+
+return