Function RDS_Layer_Actions(Action, CalcColName, FSList, Handle, Name, FMC, Record, Status, OrigRecord, Param1, Param2, Param3, Param4, Param5, Param6, Param7, Param8, Param9, Param10)
/***********************************************************************************************************************

    This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
    permission from Infineon.

    Name        :   RDS_Layer_Actions

    Description :   Handles calculated columns and MFS calls for the current table.

    Notes       :   This function uses @ID, @RECORD, and @DICT to make sure {ColumnName} references work correctly.
                    If called from outside of a calculated column these will need to be set and restored.

    Parameters  :
        Action          [in] -- Name of the action to be taken
        CalcColName     [in] -- Name of the calculated column that needs to be processed. Normally this should only be
                                populated when the CalcField action is being used.
        FSList          [in] -- The list of MFSs and the BFS name for the current file or volume. This is an @SVM
                                delimited array, with the current MFS name as the first value in the array, and the BFS
                                name as the last value. Normally set by a calling MFS.
        Handle          [in] -- The file handle of the file or media map being accessed. Note, this does contain the
                                entire handle structure that the Basic+ Open statement would provide. Normally set by a
                                calling MFS.
        Name            [in] -- The name (key) of the record or file being accessed. Normally set by a calling MFS.
        FMC             [in] -- Various functions. Normally set by a calling MFS.
        Record          [in] -- The entire record (for record-oriented functions) or a newly-created handle (for
                                "get handle" functions). Normally set by a calling MFS.
        Status      [in/out] -- Indicator of the success or failure of an action. Normally set by the calling MFS but
                                for some actions can be set by the action handler to indicate failure.
        OrigRecord      [in] -- Original content of the record being processed by the current action. This is
                                automatically being assigned by the WRITE_RECORD and DELETE_RECORD actions within
                                BASE_MFS.
        Param1-10   [in/out] -- Additional request parameter holders
        ActionFlow     [out] -- Used to control the action chain (see the ACTION_SETUP insert for more information.)
                                Can also be used to return a special value, such as the results of the CalcField
                                method.

    History     :   (Date, Initials, Notes)
        07/28/10    dmb     Original programmer.
        10/13/10    dmb     Fix logic to extract the file handle if file has an index
        03/26/11    dmb     Add logic to save and restore @FILE.ERROR

***********************************************************************************************************************/

#pragma precomp SRP_PreCompiler

$insert LOGICAL
$insert FILE.SYSTEM.EQUATES
$insert ACTION_SETUP
$insert RDS_LAYER_EQUATES

Declare function   Tool_Parms_Services, Environment_Services, Logging_Services, Memberof, Error_Services
Declare subroutine Logging_Services, Error_Services

If KeyID then GoSub Initialize_System_Variables

Begin Case
    
    Case Action _EQC 'CalcField'            ;   GoSub Calc_Field
    Case Action _EQC 'READ_RECORD_PRE'      ;   GoSub READ_RECORD_PRE
    Case Action _EQC 'READ_RECORD'          ;   GoSub READ_RECORD
    Case Action _EQC 'READONLY_RECORD_PRE'  ;   GoSub READONLY_RECORD_PRE
    Case Action _EQC 'READONLY_RECORD'      ;   GoSub READONLY_RECORD
    Case Action _EQC 'WRITE_RECORD_PRE'     ;   GoSub WRITE_RECORD_PRE
    Case Action _EQC 'WRITE_RECORD'         ;   GoSub WRITE_RECORD
    Case Action _EQC 'DELETE_RECORD_PRE'    ;   GoSub DELETE_RECORD_PRE
    Case Action _EQC 'DELETE_RECORD'        ;   GoSub DELETE_RECORD
    Case Otherwise$                         ;   Status = 'Invalid Action'
        
End Case

If KeyID then GoSub Restore_System_Variables

If Assigned(ActionFlow) else ActionFlow = ACTION_CONTINUE$

Return ActionFlow


// ----- Calculated Columns --------------------------------------------------------------------------------------------
//
// The typical structure of a calculated column will look like this:
//
// Declare function TableName_Actions
//
// A = {COL1} ; * Reference as many data columns in this way to ensure the dictionary dependency is generated.
//
// @ANS = TableName_Actions('CalcField', 'CalcColName')
//
// ---------------------------------------------------------------------------------------------------------------------

Calc_Field:
    // Make sure the ActionFlow return variable is cleared in case nothing is calculated.
    ActionFlow = ''
    
    Begin Case
        Case CalcColName EQ 'EXPORT_CONTROL'    ; GoSub EXPORT_CONTROL
    End Case
return

EXPORT_CONTROL:
    ProdSpecID      = {PS_NO}
    ExportControl   = Xlate('PROD_SPEC', ProdSpecID, 'EXPORT_CONTROL', 'X')
    If ExportControl NE True$ then ExportControl = False$
    ActionFlow      = ExportControl
return


// ----- MFS calls -----------------------------------------------------------------------------------------------------

READ_RECORD_PRE:
    // In order to stop a record from being read in this action these lines of code must be used:
    //
    //    OrigFileError   = 100 : @FM : KeyID
    //    Status          = 0
    //    Record          = ''
    //    ActionFlow      = ACTION_STOP$
return

READ_RECORD:
    // In order to stop a record from being read in this action these lines of code must be used:
    //
    //    OrigFileError   = 100 : @FM : KeyID
    //    Status          = 0
    //    Record          = ''
return

READONLY_RECORD_PRE:
    // In order to stop a record from being read in this action these lines of code must be used:
    //
    //    OrigFileError   = 100 : @FM : KeyID
    //    Status          = 0
    //    Record          = ''
    //    ActionFlow      = ACTION_STOP$
return

READONLY_RECORD:
    // In order to stop a record from being read in this action these lines of code must be used:
    //
    //    OrigFileError   = 100 : @FM : KeyID
    //    Status          = 0
    //    Record          = ''
return

WRITE_RECORD_PRE:
    
    If Not(Memberof(@User4, 'ENGINEERING')) then
        If ( (OrigRecord<RDS_LAYER_EPI_TIME_MIN$>    NE '') AND (Record<RDS_LAYER_EPI_TIME_MIN$>    EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_EPI_TIME_MAX$>    NE '') AND (Record<RDS_LAYER_EPI_TIME_MAX$>    EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_EPI_H2_FLOW_MIN$> NE '') AND (Record<RDS_LAYER_EPI_H2_FLOW_MIN$> EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_EPI_H2_FLOW_MAX$> NE '') AND (Record<RDS_LAYER_EPI_H2_FLOW_MAX$> EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_TCS_FLOW_MIN$>    NE '') AND (Record<RDS_LAYER_TCS_FLOW_MIN$>    EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_TCS_FLOW_MAX$>    NE '') AND (Record<RDS_LAYER_TCS_FLOW_MAX$>    EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_AUX1_MIN$>        NE '') AND (Record<RDS_LAYER_AUX1_MIN$>        EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_AUX1_MAX$>        NE '') AND (Record<RDS_LAYER_AUX1_MAX$>        EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_F_OFFSET_MIN$>    NE '') AND (Record<RDS_LAYER_F_OFFSET_MIN$>    EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_F_OFFSET_MAX$>    NE '') AND (Record<RDS_LAYER_F_OFFSET_MAX$>    EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_SUSC_ETCH_MIN$>   NE '') AND (Record<RDS_LAYER_SUSC_ETCH_MIN$>   EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_SUSC_ETCH_MAX$>   NE '') AND (Record<RDS_LAYER_SUSC_ETCH_MAX$>   EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_DILUENT_MIN$>     NE '') AND (Record<RDS_LAYER_DILUENT_MIN$>     EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_DILUENT_MAX$>     NE '') AND (Record<RDS_LAYER_DILUENT_MAX$>     EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_DOPANT_FLOW_MIN$> NE '') AND (Record<RDS_LAYER_DOPANT_FLOW_MIN$> EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_DOPANT_FLOW_MAX$> NE '') AND (Record<RDS_LAYER_DOPANT_FLOW_MAX$> EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_HCL_FLOW_MIN$>    NE '') AND (Record<RDS_LAYER_HCL_FLOW_MIN$>    EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_HCL_FLOW_MAX$>    NE '') AND (Record<RDS_LAYER_HCL_FLOW_MAX$>    EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_BAKE_TIME_MIN$>   NE '') AND (Record<RDS_LAYER_BAKE_TIME_MIN$>   EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_BAKE_TIME_MAX$>   NE '') AND (Record<RDS_LAYER_BAKE_TIME_MAX$>   EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_DCS_FLOW_MIN$>    NE '') AND (Record<RDS_LAYER_DCS_FLOW_MIN$>    EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_DCS_FLOW_MAX$>    NE '') AND (Record<RDS_LAYER_DCS_FLOW_MAX$>    EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_AUX2_MIN$>        NE '') AND (Record<RDS_LAYER_AUX2_MIN$>        EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_AUX2_MAX$>        NE '') AND (Record<RDS_LAYER_AUX2_MAX$>        EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_S_OFFSET_MIN$>    NE '') AND (Record<RDS_LAYER_S_OFFSET_MIN$>    EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_S_OFFSET_MAX$>    NE '') AND (Record<RDS_LAYER_S_OFFSET_MAX$>    EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_R_OFFSET_MIN$>    NE '') AND (Record<RDS_LAYER_R_OFFSET_MIN$>    EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_R_OFFSET_MAX$>    NE '') AND (Record<RDS_LAYER_R_OFFSET_MAX$>    EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_ETCH1_MIN$>       NE '') AND (Record<RDS_LAYER_ETCH1_MIN$>       EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_ETCH1_MAX$>       NE '') AND (Record<RDS_LAYER_ETCH1_MAX$>       EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_ETCH2_MIN$>       NE '') AND (Record<RDS_LAYER_ETCH2_MIN$>       EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_ETCH2_MAX$>       NE '') AND (Record<RDS_LAYER_ETCH2_MAX$>       EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_ETCH3_MIN$>       NE '') AND (Record<RDS_LAYER_ETCH3_MIN$>       EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_ETCH3_MAX$>       NE '') AND (Record<RDS_LAYER_ETCH3_MAX$>       EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_UL_TEMP_MIN$>     NE '') AND (Record<RDS_LAYER_UL_TEMP_MIN$>     EQ '') ) |
        or ( (OrigRecord<RDS_LAYER_UL_TEMP_MAX$>     NE '') AND (Record<RDS_LAYER_UL_TEMP_MAX$>     EQ '') ) then
            
            ErrorMsg    = 'RDS_LAYER specifications can only be cleared by a member of Engineering.'
            LogPath     = Environment_Services('GetApplicationRootPath') : '\LogFiles\RDS_LAYER'
            LogDate     = Oconv(Date(), 'D4/')
            LogTime     = Oconv(Time(), 'MTS')
            LogFileName = LogDate[7, 4] : '-' : LogDate[1, 2] : '-' : LogDate[4, 2] : ' RDS_LAYER_Spec_Clear_Attempt_Log.csv'
            Headers     = 'Logging DTM' : @FM : 'User' : @FM : 'RDS_LAYER Key ID' : @FM : 'Notes'
            objLog      = Logging_Services('NewLog', LogPath, LogFileName, CRLF$, Comma$, Headers, '', False$, False$)
            LoggingDTM  = LogDate : ' ' : LogTime   ; // Logging DTM
            
            LogData    = ''
            LogData<1> = LoggingDTM
            LogData<2> = @USER4
            LogData<3> = Name
            LogData<4> = ErrorMsg
            LogData<5> = Error_Services('GetStackTrace')
            Logging_Services('AppendLog', ObjLog, LogData, @RM, @FM, False$)
            Error_Services('LogStack')
            Error_Services('Add', ErrorMsg)
            
            OrigFileError = 104:': ':ErrorMsg
            Status        = 0
            Record        = ''
            ActionFlow  = ACTION_STOP$
            
        end
    end
    
return

WRITE_RECORD:
return

DELETE_RECORD_PRE:
return

DELETE_RECORD:
return


// ----- Internal Methods ----------------------------------------------------------------------------------------------

Initialize_System_Variables:
    
    // Save these for restoration later
    SaveDict        = @DICT
    SaveID          = @ID
    SaveRecord      = @RECORD
    OrigFileError   = @FILE.ERROR
    
    // Now make sure @DICT, ID, and @RECORD are populated
    CurrentDictName = ''
    If @DICT then
        DictHandle = @DICT<1, 2>
        Locate DictHandle in @TABLES(5) Using @FM Setting fPos then
            CurrentDictName = Field(@TABLES(0), @FM, fPos, 1)
        end
    end
    
    If CurrentDictName NE DictName then
        Open DictName to @DICT else Status = 'Unable to initialize @DICT'
    end    
    
    @ID = KeyID
    If Record else
        // Record might not have been passed in. Read the record from the database table just to make sure.
        @FILE.ERROR     = ''
        Open TableName to hTable then
            FullFSList  = hTable[1, 'F' : @VM]
            BFS         = FullFSList[-1, 'B' : @SVM]
            LastHandle  = hTable[-1, 'B' : \0D\]
            FileHandle  = \0D\ : LastHandle[1, @VM]
            
            Call @BFS(READO.RECORD, BFS, FileHandle, KeyID, FMC, Record, ReadOStatus)
        end
    end
    @RECORD = Record
    
return


Restore_System_Variables:
    
    Transfer SaveDict   to @DICT
    Transfer SaveID     to @ID
    Transfer SaveRecord to @RECORD
    @FILE.ERROR = OrigFileError

return

