Function Config_API(@API)
/***********************************************************************************************************************

    This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
    permission from SRP Computer Solutions, Inc.

    Name        :   Config_API

    Description :   API logic for the Config resource.

    Notes       :   All web APIs should include the API_SETUP insert. This will provide several useful variables:

                        HTTPMethod              - The HTTP Method (Verb) submitted by the client (e.g., GET, POST, etc.)
                        APIURL                  - The URL for the API entry point (e.g., api.mysite.com/v1).
                        FullEndpointURL         - The URL submitted by the client, including query params.
                        FullEndpointURLNoQuery  - The URL submitted by the client, excluding query params.
                        EndpointSegment         - The URL endpoint segment.
                        ParentURL               - The URL path preceeding the current endpoint.
                        CurrentAPI              - The name of this stored procedure.

    Parameters  :
        API             [in] -- Web API to process. Format is [APIPattern].[HTTPMethod]:
                                    - APIPattern must follow this structure Config[.ID.[<Property>]]
                                    - HTTPMethod can be any valid HTTP method, e.g., GET, POST, PUT, DELETE, etc.
                                Examples:
                                    - Config.POST
                                    - Config.ID.PUT
                                    - Config.ID.firstName.GET
        Response       [out] -- Response to be sent back to the Controller (HTTP_MCP) or requesting procedure. Web API
                                services do not rely upon anything being returned in the response. This is what the
                                various services like SetResponseBody and SetResponseStatus services are for. A response
                                value is only helpful if the developers want to use it for debug purposes.

    History     :   (Date, Initials, Notes)
        01/05/23    djs     Original programmer.

***********************************************************************************************************************/

#pragma precomp SRP_PreCompiler

$insert APP_INSERTS
$insert API_SETUP
$insert HTTP_INSERTS

Declare function   OI_Wizard_Services, Config_Services, MemberOf
Declare subroutine Config_Services

GoToAPI else
    // The specific resource endpoint doesn't have a API handler yet.
    HTTP_Services('SetResponseStatus', 204, 'This is a valid endpoint but a web API handler has not yet been created.')
end

Return Response OR ''


////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Endpoint Handlers
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////


API config.ID.HEAD
API config.ID.GET

    StatusCode = 200
    GoSub CreateHALItem

end api


API config.ID.PUT

    OIWizardID = ''
    Cookies    = HTTP_Services('GetHTTPCookie')
    For each Cookie in Cookies using ';'
        Key = Trim(Field(Cookie, '=', 1))
        If Key EQ 'sessionID' then
            OIWizardID = Field(Cookie, '=', 2)
        end
        If Key EQ 'userID' then
            CurrUser = Field(Cookie, '=', 2)
        end else
        	If OIWizardID NE '' then CurrUser = Xlate('OI_WIZARD', OIWizardID, 'EMPLOYEE_ID', 'X')
        end
    Next Cookie
    
    ValidSession = OI_Wizard_Services('ValidateSession', OIWizardID)

    If ValidSession then
        StatusCode = 200
        GoSub UpdateHALItem
    end else
        HTTP_Services('SetResponseStatus', 401, 'Invalid session. Reauthentication required.')
    end

end api


////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Internal GoSubs
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////


//----------------------------------------------------------------------------------------------------------------------
// CreateHALItem
//
// Creates a HAL+JSON object based on the OpenInsight config data row.
//----------------------------------------------------------------------------------------------------------------------
CreateHALItem:
    
    ConfigID = EndpointSegment
    
    Begin Case
        Case ConfigID _EQC 'OEE'
            JSONResponse = Config_Services('GetOEE', FullEndpointURL)
        Case ConfigID _EQC 'MaterialTrack'
			OIWizardID = ''
			CurrUser   = ''
			Cookies    = HTTP_Services('GetHTTPCookie')
			For each Cookie in Cookies using ';'
				Key = Trim(Field(Cookie, '=', 1))
				If Key EQ 'sessionID' then
					OIWizardID = Field(Cookie, '=', 2)
				end
				If Key EQ 'userID' then
					CurrUser = Field(Cookie, '=', 2)
				end else
					If OIWizardID NE '' then CurrUser = Xlate('OI_WIZARD', OIWizardID, 'EMPLOYEE_ID', 'X')
				end
			Next Cookie        	
        	JSONResponse = Config_Services('GetMaterialTrackSettings', CurrUser)
        Case Otherwise$
            Error_Services('Add', 'Unsupported configID')
    End Case

    If Error_Services('NoError') then
        HTTP_Services('SetResponseHeaderField', 'Content-Location', FullEndpointURL)
        HTTP_Services('SetResponseBody', JSONResponse, False$, 'application/hal+json')
        If Assigned(Message) then
            HTTP_Services('SetResponseStatus', StatusCode, Message)
        end else
            HTTP_Services('SetResponseStatus', StatusCode)
        end
    end else
        Message = Error_Services('GetMessage')          
        HTTP_Services('SetResponseStatus', 500, 'Error in the ' : CurrentAPI : ' API. Message: ': Message)
    end

return


//----------------------------------------------------------------------------------------------------------------------
// UpdateHALItem
//
// Updates a HAL+JSON object based on the OpenInsight config data row.
//----------------------------------------------------------------------------------------------------------------------
UpdateHALItem:
    
    JsonResponse = ''
    ConfigID     = EndpointSegment
    
    Begin Case
        Case ConfigID _EQC 'OEE'
            // Ensure user is authorized to update OEE setpoints
            Authorized  = False$
            ValidGroups = 'SUPERVISOR,LEAD,OI_ADMIN'
            LSLUser     = Xlate('OI_WIZARD', OIWizardID, 'EMPLOYEE_ID', 'X')
            For each ValidGroup in ValidGroups using ','
                If MemberOf(LslUser, ValidGroup) then
                    Authorized = True$
                end
            Until Authorized
            Next ValidGroup
            If Authorized then
                // The resource will have been put into the POST string.
                Body    = HTTP_Services('GetHTTPPostString')
                If Body NE '' then
                    // The POST string will have been encoded so use percent (URL) decoding.
                    OEEjson      = HTTP_Services('DecodePercentString', Body)
                    Config_Services('UpdateOEE', OEEjson)
                    JsonResponse = OEEjson
                end else
                    Error_Services('Add', 'No body was sent with the request.')
                end
            end else
                Error_Services('Add', 'User is not authorized to update OEE setpoints.')
            end
        Case ConfigID _EQC 'MaterialTrack'
        	// The resource will have been put into the POST string.
			Body    = HTTP_Services('GetHTTPPostString')
			If Body NE '' then
				// The POST string will have been encoded so use percent (URL) decoding.
				MtSettingsJson = HTTP_Services('DecodePercentString', Body)
				Config_Services('UpdateMaterialTrackSettings', MtSettingsJson, CurrUser)
			end else
				Error_Services('Add', 'No body was sent with the request.')
			end        	
        	
        Case Otherwise$
            Error_Services('Add', 'Unsupported configID')
    End Case

    If Error_Services('NoError') then
        HTTP_Services('SetResponseHeaderField', 'Content-Location', FullEndpointURL)
        HTTP_Services('SetResponseBody', JsonResponse, False$, 'application/hal+json')
        If Assigned(Message) then
            HTTP_Services('SetResponseStatus', StatusCode, Message)
        end else
            HTTP_Services('SetResponseStatus', StatusCode)
        end
    end else
        Message = Error_Services('GetMessage')          
        HTTP_Services('SetResponseStatus', 500, 'Error in the ' : CurrentAPI : ' API. Message: ': Message)
    end
    
return

