Compile Function NDW_RDS_Quick_Query_Events(CtrlEntId, Event, @PARAMS)
/***********************************************************************************************************************

    This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
    permission from Infineon.

    Name        :   NDW_RDS_Quick_Query_Events

    Description :   This function acts as a commuter module for all events related to this window.

    Notes       :   Commuter Modules are automatically called from the Promoted_Events function which is called by the
                    application-specific promoted event handler. This makes it possible to add QuickEvents that need to
                    execute Basic+ logic without having use the Form Designer to make the association, although this is
                    limited to the events which are currently promoted.

                    If the form needs to call the commuter module directly then the QuickEvent parameters should be
                    formatted like this:

                        '@SELF','@EVENT',['@PARAM1','@PARAMx']

    Parameters  :
        CtrlEntId   [in] -- The fully qualified name of the control calling the promoted event
        Event       [in] -- The event being executed. See the Notes section regarding "PRE" events
        Param1-15   [in] -- Additional event parameter holders
        EventFlow  [out] -- Set to 1 or 0 so the calling event knows whether or not to chain forward. See comments in
                            EVENT_SETUP insert

    History     :   (Date, Initials, Notes)
        09/08/22    djs     Created initial commuter module.

***********************************************************************************************************************/

#pragma precomp SRP_PreCompiler
#Window NDW_RDS_QUICK_QUERY

$insert APP_INSERTS
$insert EVENT_SETUP
$insert WO_MAT_EQUATES
$insert MSG_EQUATES

equ WOCust$ to 2

Declare subroutine  SRP_Show_Window, Rds_Services, ErrMsg, Start_Window
Declare function    Database_Services, Material_Services, Rds_Services, RGB, SRP_Array, MemberOf

SubclassInfo    = Form_Services('FindSubclassControl')
Subclass        = SubclassInfo<1>

// Update the arguments so that the OpenInsight OLE event will treate the ActiveX event as a native event handler.
If Event EQ 'OLE' then
    Transfer Event to OIEvent
    Transfer Param1 to Event
    Transfer Param2 to Param1
    Transfer Param3 to Param2
*    Transfer Param4 to Param3
*    Transfer Param5 to Param4
*    Transfer Param6 to Param5
*    Transfer Param7 to Param6
*    Transfer Param8 to Param7
end

GoToEvent Event for CtrlEntID

Return EventFlow else EVENT_CONTINUE$


////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Events
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

Event WINDOW.CREATE(CreateParam)
    
    Swap @VM with @FM in CreateParam
    Begin Case
        Case RowExists('WO_LOG', CreateParam<1>)
            ThisWorkOrderNo = CreateParam<1>
            RDSOverrideList = ''
        Case RowExists('RDS', CreateParam<1>)
            ThisWorkOrderNo = ''
            RDSOverrideList = CreateParam<1>
    End Case
    
    If (DCount(CreateParam, @FM) > 1) then
    	Set_Property(@Window:'.RAG_VIEW', 'VALUE', CreateParam<2>)
    end
    
    GoSub GetRdsColumns
    
    RDSList         = RDS_Services('GetRDSData', ThisWorkOrderNo, RDSColumns, True$, RDSOverrideList)   
	RDSRptCtrl      = @Window : '.OLE_RPT_RDS_LIST'
	
	GoSub Setup_OLE_Controls
	
	OrigSize = Get_Property(@Window, 'SIZE')
	Set_Property(@Window, '@ORIG_SIZE', OrigSize)
	
	// Turn off AutoPopulate for performance reasons
	Set_Property(RDSRptCtrl, 'OLE.AutoPopulate', False$)
	
	Set_Property(@Window:'.EDL_SEARCH', 'TEXT', ThisWorkOrderNo)
	
	SRP_Show_Window(@Window, 'SYSTEM', 'C', 'C', 1, '', False$, False$, FormSize)
		
	// Turn AutoPopulate back on
	Set_Property(RDSRptCtrl, 'OLE.AutoPopulate', True$)
	Set_Property(RDSRptCtrl, "OLE.AlwaysShowSelection", True$)
	Send_Message(RDSRptCtrl, "OLE.UnselectAll")
	Send_Message(@Window, "SET_ZORDER", '')

end event


Event WINDOW.CLOSE(CancelFlag)
    
    Result = ''
    // Perhaps add a savewarn prompt if list has been edited.
    End_Dialog(@Window, Result)
    
end event


Event PUB_OK.CLICK()

    SelRDSList = Get_Property(@Window : '.OLE_RPT_RDS_LIST', 'OLE.SelList')
    SelRDSList = SRP_Array('Rotate', SelRDSList, @FM, @VM)
    RDSKeys    = SelRDSList<4>
    Start_Window('RDS', @window, RDSKeys:'*CENTER')

end event


Event PUB_CANCEL.CLICK()

    Result = ''
    // Perhaps add a savewarn prompt if list has been edited.
    End_Dialog(@Window, Result)

end event


Event PUB_SELECT_ALL.CLICK()
    
    Send_Message(@Window : '.OLE_RPT_RDS_LIST', "OLE.SelectAll")
    Set_Property(@Window : '.OLE_RPT_RDS_LIST', 'OLE.Focus', True$)

end event


Event PUB_CLEAR.CLICK()

    Send_Message(@Window : '.OLE_RPT_RDS_LIST', "OLE.UnselectAll")

end event


Event PUB_ENG_OPTIONS.CLICK()
    
    SelOpt = Popup(@Window, '', 'ENG_OPTIONS')
    
    If SelOpt NE '' then
        
        SelRDSList = Get_Property(@Window : '.OLE_RPT_RDS_LIST', 'OLE.SelList')
        SelRDSList = SRP_Array('Rotate', SelRDSList, @FM, @VM)
        SelWO      = SelRDSList<2>
        SelCass    = SelRDSList<6>
        WOMatKeys  = ''
        If SelWO NE '' then
            For each WONo in SelWO using @VM setting vPos
                WOMatKeys<0, -1> = WONo:'*':SelCass<0 , vPos>
            Next WONo
        end
        
        NumRows = DCount(WOMatKeys, @VM)
        
        Begin Case
            
            Case SelOpt EQ 'CLEAN_INSP'
                
                Caption        = "Updating Clean & Insp specs for selected RDS cassettes..."
                ServiceModules = 'CLEAN_INSP_SERVICES'
                Services       = 'UpdateAllCleanInsp'
                 
            Case SelOpt EQ 'QA_MET'
                
                Caption        = "Updating QA Metrology specs for selected RDS cassettes..."
                ServiceModules = 'WO_MAT_QA_SERVICES'
                Services       = 'UpdateQAMet'
                
            Case SelOpt EQ 'CLEAN_INSP':@VM:'QA_MET'
                Caption        = "Updating Clean & Insp and QA Metrology specs for selected RDS cassettes..."
                ServiceModules = 'CLEAN_INSP_SERVICES':@VM:'WO_MAT_QA_SERVICES'
                Services       = 'UpdateAllCleanInsp':@VM:'UpdateQAMet'
                
        End Case
        
        If ServiceModules NE '' then
            Def              = ""
            Def<MCAPTION$>   = Caption
            Def<MTYPE$>      = "GC"
            Def<MEXTENT$>    = NumRows
            Def<MTEXTWIDTH$> = 600
            MsgUp            = Msg(@WINDOW, Def) ;* Start gas guage message
            For each WOMatKey in WOMatKeys using @VM setting vPos
                Running = Msg(@WINDOW, MsgUp, vPos, MSGINSTUPDATE$) ;* Update gas guage
                For each ServiceModule in ServiceModules using @VM setting sPos
                    Service = Services<0, sPos>
                    Ans     = Function(@ServiceModule(Service, WOMatKey))
                    If Error_Services('HasError') then
                        Error_Services('DisplayError')
                    end
                Next ServiceModule
            Next WOMatKey
            Msg(@WINDOW,MsgUp) ;* Take gas guage down
        end
        
        If Error_Services('NoError') then
            Def            = ""
            Def<MICON$>    = '*'
            Def<MCAPTION$> = 'Success'
            Def<MTEXT$>    = "Update complete!"
            Def<MTYPE$>    = "BO"
            MsgUp          = Msg(@window, Def)
        end
    end
    
end event


Event OLE_SUBCLASS.OnComboClick(CtrlId, Sel, Value)

    Send_Event(CtrlId, 'LOSTFOCUS')

end event


Event OLE_RPT_RDS_LIST.OnSelChange()
    
    If MemberOf(@User4, 'ENGINEERING') then
        SelRDSList = Get_Property(@Window : '.OLE_RPT_RDS_LIST', 'OLE.SelList')
        Enabled    = (SelRDSList NE '')
        Set_Property(@Window:'.PUB_ENG_OPTIONS', 'ENABLED', Enabled)
    end

end event


Event PUB_RUN.CLICK()
	
	GoSub GetRdsColumns

	Set_Property(@Window : '.OLE_RPT_RDS_LIST', 'OLE.List', '')
	Set_Property(@Window, '@OrigList', '')
	
	WoNo = ''
	
	SearchBy = Get_Property(@Window:'.RAG_SEARCH_BY', 'VALUE')
	SearchValue = Get_Property(@Window:'.EDL_SEARCH', 'TEXT')
	If SearchBy _EQC 'reactor' then
		ReactorConfigKey = 'WO_DAILY_SCHED':SearchValue
		WoNo = Field(Xlate('CONFIG', ReactorConfigKey, WOCust$, 'X'), ' ', 1)
	end
	
	If SearchBy _EQC 'wono' then
		WoNo = SearchValue
	end
	
	RDSList = ''
	If WoNo then
		RDSList = RDS_Services('GetRDSData', WoNo, RDSColumns, True$, '')
	end
	
	RDSRptCtrl      = @Window : '.OLE_RPT_RDS_LIST'
	
	GoSub Setup_OLE_Controls
	
	// Turn off AutoPopulate for performance reasons
	Set_Property(RDSRptCtrl, 'OLE.AutoPopulate', False$)
	
	SRP_Show_Window(@Window, 'SYSTEM', 'C', 'C', 1, '', False$, False$, FormSize)
		
	// Turn AutoPopulate back on
	Set_Property(RDSRptCtrl, 'OLE.AutoPopulate', True$)
	Set_Property(RDSRptCtrl, "OLE.AlwaysShowSelection", True$)
	Send_Message(RDSRptCtrl, "OLE.UnselectAll")
	Send_Message(@Window, "SET_ZORDER", '')
	
end event


////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Internal GoSubs
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
Setup_OLE_Controls:

    Qualify     = ''
    Qualify<1>  = 1
    Qualify<4>  = 0

    RDSRptCtrl          = @Window : '.OLE_RPT_RDS_LIST'
    RDSPicCtrl          = @Window : '.OLE_PIC_RDS_LIST_DIV'
    
    // Qualify OLE events that we want to intercept
    Qualifier = ''
    Qualifier<1> = 1
    Qualifier<4> = 0 ; * process synchronously (i.e. immediately)
    Send_Message(RDSRptCtrl, 'QUALIFY_EVENT', 'OLE.OnSelChange', Qualifier)
    
    GoSub GetColumnList
    
    Set_Property(RDSRptCtrl, 'OLE.ColumnList', ColumnList)
    Set_Property(RDSRptCtrl, 'OLE.MultiSelect', 2)  ; // 2 = Multiselect Toggle Mode
    
    NumCols = DCount(ColumnList, @FM)
    For ColIndex = 1 to NumCols
        Set_Property(RDSRptCtrl, "OLE.ColumnHeaderAlignment[":ColIndex:"]", 'C')
    Next ColIndex
    
    // Get the design time form size. This will be adjusted based on the number of RDS records.
    FormSize            = Get_Property(@Window, '@ORIG_SIZE')
    RDSRptCtrlSize      = Get_Property(RDSRptCtrl, 'SIZE')
    NumRDS              = DCount(RDSList, @FM)
    
    // Adjust the form and ReportTable control size based on the number of RDS records in the work order.
    AdditionalRowsAdj   = 0
    AdditionalRowsAdj += (NumRDS - 1) * 20
   
    // Ensure window and controls are sized within client machine's max resolution.
    ProposedNewHeight = FormSize<4> + AdditionalRowsAdj
    SystemWindowSize  = Get_Property('SYSTEM', 'SIZE')
    MaxClientHeight   = SystemWindowSize<4>
    If ProposedNewHeight > MaxClientHeight then
        FormSize<4> = Oconv(MaxClientHeight * '0.9', 'MD0')
    end else
        FormSize<4> = FormSize<4> + AdditionalRowsAdj
    end
    MaxClientWidth    = SystemWindowSize<3>
    If FormSize<3> > MaxClientWidth then
        FormSize<3> = Oconv(MaxClientWidth * '0.9', 'MD0')
    end
    Set_Property(@Window, '@ORIGSIZE', FormSize)      
    // Pull then save original list after formatting for savewarn purposes
    Set_Property(RDSRptCtrl, 'OLE.List', RDSList)
    RDSList  = Get_Property(@Window : '.OLE_RPT_RDS_LIST', 'OLE.List')
    Set_Property(@Window, '@OrigList', RDSList)
    GoSub RefreshRowColors
    
return
    
    
RefreshRowColors:
        
    RDSRptCtrl  = @Window : '.OLE_RPT_RDS_LIST'
    NumRDS      = DCount(RDSList, @FM)
    
    // Fill report table with RDS data
    Set_Property(RDSRptCtrl, 'OLE.List', RDSList)
           
    // Color every other cell to increase row distinguishability
    Colors = ''
    If NumRDS GT 1 then
        For RowNo = 1 To NumRDS
            If Mod(RowNo, 2) EQ 1 then Colors<RowNo> = RGB(231, 243, 254) else Null ; // light blue       
        Next RowNo
        Set_Property(RDSRptCtrl, 'OLE.RecordColors', Colors)
    end
    
    // Clear any selected rows
    SelPos = ''
    Set_Property(@Window : '.OLE_RPT_RDS_LIST', 'OLE.SelPos', SelPos)
    
return


GetRdsColumns:
	GoSub GetView
	If CurrentViewSelection _EQC 'quick' then
		RDSColumns        = ''
		RDSColumns<0, 1>  = 'ABBREV_OR_CO_NAME'
		RDSColumns<0, 2>  = 'WO'
		RDSColumns<0, 3>  = 'WO_STEP'
		RDSColumns<0, 4>  = 'SEQ'
		RDSColumns<0, 5>  = 'REACTOR'
		RDSColumns<0, 6>  = 'RUN_ORDER_NUM'
		RDSColumns<0, 7>  = 'UNLOAD_THICK_TEST'
		RDSColumns<0, 8>  = 'HGCV_TEST'
		RDSColumns<0, 9>  = 'DATE_IN'
		RDSColumns<0, 10> = 'TIME_IN'
		RDSColumns<0, 11> = 'DATE_OUT'
		RDSColumns<0, 12> = 'TIME_OUT'
		RDSColumns<0, 13> = 'PART_NUM'
		RDSColumns<0, 14> = 'LOT_NUM'
	end else
		RDSColumns        = ''
		RDSColumns<0, 1>  = 'ABBREV_OR_CO_NAME'
		RDSColumns<0, 2>  = 'WO'
		RDSColumns<0, 3>  = 'WO_STEP'
		RDSColumns<0, 4>  = 'SEQ'
		RDSColumns<0, 5>  = 'REACTOR'
		RDSColumns<0, 6>  = 'RUN_ORDER_NUM'
		RDSColumns<0, 7>  = 'UNLOAD_THICK_TEST'
		RDSColumns<0, 8>  = 'HGCV_TEST'
		RDSColumns<0, 9>  = 'DATE_IN'
		RDSColumns<0, 10> = 'TIME_IN'
		RDSColumns<0, 11> = 'DATE_OUT'
		RDSColumns<0, 12> = 'TIME_OUT'
		RDSColumns<0, 13> = 'ELAPSED_HOURS'
		RDSColumns<0, 14> = 'PART_NUM'
		RDSColumns<0, 15> = 'LOT_NUM'
		RDSColumns<0, 16> = 'COMB_STATUS'
		RDSColumns<0, 17> = 'NCR_SUM'
		RDSColumns<0, 18> = 'NCR_REJ_CNT'
		RDSColumns<0, 19> = 'HOLD_STATUS'
	end
return


GetColumnList:
	GoSub GetView
	If CurrentViewSelection _EQC 'quick' then
		ColumnList     = ''
		ColumnList<1>  = 'Customer' : @VM : 'TEXT' : @VM : 150 : @VM : @VM : @VM : @VM : @VM : @VM : 50 : @VM : 'Left' : @VM : @VM : @VM : @VM : 'Segoe UI,9'
		ColumnList<2>  = 'WO No' : @VM : 'NUMBER' : @VM : 50 : @VM : @VM : @VM : @VM : @VM : @VM : 50 : @VM : 'Center' : @VM : @VM : '#######' : @VM : @VM : 'Segoe UI,9'
		ColumnList<3>  = 'Step' : @VM : 'NUMBER' : @VM : 30 : @VM : @VM : @VM : @VM : @VM : @VM : 30 : @VM : 'Center' : @VM : @VM : '##': @VM : @VM : 'Segoe UI,9'
		ColumnList<4>  = 'RDS' : @VM : 'NUMBER' : @VM : 60 : @VM : @VM : @VM : @VM : @VM : @VM : 30 : @VM : 'Center' : @VM : @VM : '###' : @VM : @VM : 'Segoe UI,9'
		ColumnList<5>  = 'Rx' : @VM : 'NUMBER' : @VM : 30 : @VM : @VM : @VM : @VM : @VM : @VM : 50 : @VM : 'Center' : @VM : @VM : '#######' : @VM : @VM : 'Segoe UI,9'
		ColumnList<6>  = 'Run' : @VM : 'NUMBER' : @VM : 30 : @VM : @VM : @VM : @VM : @VM : @VM : 25 : @VM : 'Center' : @VM : @VM :'##': @VM : @VM : 'Segoe UI,9'
		ColumnList<7>  = 'UL Thk' : @VM : 'BOOL' : @VM : 30 : @VM : @VM : @VM : @VM : @VM : @VM : 40 : @VM : 'Center' : @VM : @VM : 'Yes' : @VM : @VM : 'Segoe UI,9'
		ColumnList<8>  = 'HgCv' : @VM : 'BOOL' : @VM : 30 : @VM : @VM : @VM : @VM : @VM : @VM : 40 : @VM : 'Center' : @VM : @VM : 'Yes' : @VM : @VM : 'Segoe UI,9'
		ColumnList<9>  = 'Date In' : @VM : 'DATE' : @VM : 55 : @VM : @VM : @VM : @VM : @VM : @VM : 60 : @VM : 'Center' : @VM : @VM : 'MM/DD/YY' : @VM : @VM : 'Segoe UI,9'
		ColumnList<10> = 'Time In' : @VM : 'TIME' : @VM : 55 : @VM : @VM : @VM : @VM : @VM : @VM : 60 : @VM : 'Center' : @VM : @VM : 'hh:mmAA' : @VM : @VM : 'Segoe UI,9'
		ColumnList<11> = 'Date Out' : @VM : 'DATE' : @VM : 55 : @VM : @VM : @VM : @VM : @VM : @VM : 60 : @VM : 'Center' : @VM : @VM : 'MM/DD/YY': @VM : @VM : 'Segoe UI,9'
		ColumnList<12> = 'Time Out' : @VM : 'TIME' : @VM : 55 : @VM : @VM : @VM : @VM : @VM : @VM : 60 : @VM : 'Center' : @VM : @VM : 'hh:mmAA': @VM : @VM : 'Segoe UI,9'
		ColumnList<13> = 'Cust Part No' : @VM : 'TEXT' : @VM : 75 : @VM : @VM : @VM : @VM : @VM : @VM : 75 : @VM : 'Center' : @VM : @VM : @VM : @VM : 'Segoe UI,9'
		ColumnList<14> = 'Lot Number' : @VM : 'TEXT' : @VM : 100 : @VM : @VM : @VM : @VM : @VM : @VM : 75 : @VM : 'Center' : @VM : @VM : @VM : @VM : 'Segoe UI,9'
	end else
		ColumnList          = ''
		ColumnList<1>       = 'Customer' : @VM : 'TEXT' : @VM : 150 : @VM : @VM : @VM : @VM : @VM : @VM : 50 : @VM : 'Left' : @VM : @VM : @VM : @VM : 'Segoe UI,9'
		ColumnList<2>       = 'WO No' : @VM : 'NUMBER' : @VM : 50 : @VM : @VM : @VM : @VM : @VM : @VM : 50 : @VM : 'Center' : @VM : @VM : '#######' : @VM : @VM : 'Segoe UI,9'
		ColumnList<3>       = 'Step' : @VM : 'NUMBER' : @VM : 30 : @VM : @VM : @VM : @VM : @VM : @VM : 30 : @VM : 'Center' : @VM : @VM : '##': @VM : @VM : 'Segoe UI,9'
		ColumnList<4>       = 'RDS' : @VM : 'NUMBER' : @VM : 75 : @VM : @VM : @VM : @VM : @VM : @VM : 30 : @VM : 'Center' : @VM : @VM : '###' : @VM : @VM : 'Segoe UI,9'
		ColumnList<5>       = 'Rx' : @VM : 'NUMBER' : @VM : 30 : @VM : @VM : @VM : @VM : @VM : @VM : 50 : @VM : 'Center' : @VM : @VM : '#######' : @VM : @VM : 'Segoe UI,9'
		ColumnList<6>       = 'Run' : @VM : 'NUMBER' : @VM : 30 : @VM : @VM : @VM : @VM : @VM : @VM : 25 : @VM : 'Center' : @VM : @VM :'##': @VM : @VM : 'Segoe UI,9'
		ColumnList<7>       = 'UL Thk' : @VM : 'BOOL' : @VM : 55 : @VM : @VM : @VM : @VM : @VM : @VM : 40 : @VM : 'Center' : @VM : @VM : 'Yes' : @VM : @VM : 'Segoe UI,9'
		ColumnList<8>       = 'HgCv' : @VM : 'BOOL' : @VM : 50 : @VM : @VM : @VM : @VM : @VM : @VM : 40 : @VM : 'Center' : @VM : @VM : 'Yes' : @VM : @VM : 'Segoe UI,9'
		ColumnList<9>       = 'Date In' : @VM : 'DATE' : @VM : 55 : @VM : @VM : @VM : @VM : @VM : @VM : 60 : @VM : 'Center' : @VM : @VM : 'MM/DD/YY' : @VM : @VM : 'Segoe UI,9'
		ColumnList<10>      = 'Time In' : @VM : 'TIME' : @VM : 55 : @VM : @VM : @VM : @VM : @VM : @VM : 60 : @VM : 'Center' : @VM : @VM : 'hh:mmAA' : @VM : @VM : 'Segoe UI,9'
		ColumnList<11>      = 'Date Out' : @VM : 'DATE' : @VM : 55 : @VM : @VM : @VM : @VM : @VM : @VM : 60 : @VM : 'Center' : @VM : @VM : 'MM/DD/YY': @VM : @VM : 'Segoe UI,9'
		ColumnList<12>      = 'Time Out' : @VM : 'TIME' : @VM : 55 : @VM : @VM : @VM : @VM : @VM : @VM : 60 : @VM : 'Center' : @VM : @VM : 'hh:mmAA': @VM : @VM : 'Segoe UI,9'
		ColumnList<13>      = 'Elapsed Hours' : @VM : 'TEXT' : @VM : 75 : @VM : @VM : @VM : @VM : @VM : @VM : 50 : @VM : 'Center' : @VM : @VM : @VM : @VM : 'Segoe UI,9'
		ColumnList<14>      = 'Cust Part No' : @VM : 'TEXT' : @VM : 75 : @VM : @VM : @VM : @VM : @VM : @VM : 75 : @VM : 'Center' : @VM : @VM : @VM : @VM : 'Segoe UI,9'
		ColumnList<15>      = 'Lot Number' : @VM : 'TEXT' : @VM : 100 : @VM : @VM : @VM : @VM : @VM : @VM : 75 : @VM : 'Center' : @VM : @VM : @VM : @VM : 'Segoe UI,9'
		ColumnList<16>      = 'Combined Status' : @VM : 'TEXT' : @VM : 125 : @VM : @VM : @VM : @VM : @VM : @VM : 125 : @VM : 'Left' : @VM : @VM : @VM : @VM : 'Segoe UI,9'
		ColumnList<17>      = 'NCR Status' : @VM : 'TEXT' : @VM : 75 : @VM : @VM : @VM : @VM : @VM : @VM : 30 : @VM : 'Center' : @VM : @VM : @VM : @VM : 'Segoe UI,9'
		ColumnList<18>      = 'NCR Wfr Cnt' : @VM : 'NUMBER' : @VM : 75 : @VM : @VM : @VM : @VM : @VM : @VM : 30 : @VM : 'Center' : @VM : @VM : @VM : @VM : 'Segoe UI,9'
		ColumnList<19>      = 'Hold Status' : @VM : 'TEXT' : @VM : 75 : @VM : @VM : @VM : @VM : @VM : @VM : 40 : @VM : 'Center' : @VM : @VM : @VM : @VM : 'Segoe UI,9'
	end
return

GetView:
	CurrentViewSelection = Get_Property(@Window:'.RAG_VIEW', 'VALUE')
return






