COMPILE SUBROUTINE Print_BC_WallSheet( Dummy )

DECLARE FUNCTION set_printer, get_printer, msg, fieldcount, Printer_Select, obj_Install
DECLARE SUBROUTINE security_err_msg


$INSERT OIPRINT_EQUATES
$INSERT MSG_EQUATES

EQU PI$LEFT		TO 1
EQU PI$TOP		TO 2
EQU PI$RIGHT	TO 3
EQU PI$BOTTOM	TO 4
EQU PI$WIDTH	TO 5
EQU PI$HEIGHT	TO 6
EQU PI$SIZE		TO 7


PrintPath = Printer_Select('',1)	;* Returns the path for the default printer

* * *   PRINT SETUP   * * *

PageInfo	= ''
PageInfo<PI$LEFT>	= '0.5'
PageInfo<PI$TOP>	= '1.35'
PageInfo<PI$RIGHT>	= '0.5'
PageInfo<PI$BOTTOM>	= '0.25'

PageSetup	= 0				;* 0 = Portrait, 1 = Landscape mode
PrintSetup	= 0				;* 0 = No Preview, 2 = Preview


stat = Set_Printer("INIT",'Printing','Bar Code Wall Sheet',PageInfo,PageSetup,PrintSetup,PrintPath)


  
font = 'Arial'		;* Font basics
font<2> = 10
font<4> = 0

stat = Set_Printer('FONTHEADFOOT', font)

stat = Set_Printer('LINESTYLE', PS_SOLID:@FM:2)
stat = Set_Printer('LINE', -0.1:@FM:-1.2:@FM:7.5:@FM:-1.2, 1)
stat = Set_Printer('LINE', -0.1:@FM:-0.1:@FM:7.5:@FM:-0.1, 1)
 
location = -.15:@fm:-1.150:@fm:1.57:@fm:1
stat = Set_Printer('BMP',obj_Install('Get_Prop','ColorBMP'),location, 0,1)


* * * *  Added 10/8/2015 JCH - Updated 'CONFIG','COMPANY'  * * * *

InstDat		= obj_Install('Get_Prop','Company':@FM:'Division')
Company		= InstDat<1>
Division	= InstDat<2>
	
font	= 'Arial'
font<2>	= '12'		;* Big type
font<4>	= 1			;* Bold on
font<5> = 0			;* Italics

stat = Set_Printer('TEXTXY',Company,5.7:@FM:-1.15,font,1)
stat = Set_Printer('TEXTXY',Division,5.7:@FM:-0.970,font,1)

font<2> = 10	;* 10 point font
font<4> = 0		;* Bold off
font<5> = 0		;* Italics Off

stat = Set_Printer('TEXTXY',obj_Install('Get_Prop','Address'), 5.7:@fm:-0.775, font,1)
stat = Set_Printer('TEXTXY',obj_Install('Get_Prop','CSZC'), 5.7:@fm:-0.625, font,1)
stat = Set_Printer('TEXTXY','Tel:      ':obj_Install('Get_Prop','Phone'), 5.7:@fm:-0.475, font, 1)
stat = Set_Printer('TEXTXY','FAX:    ':obj_Install('Get_Prop','FAX'), 5.7:@fm:-0.325, font, 1)

* * * *  End of changes 10/8/2015 JCH  * * * *

font	= 'Arial'
font<2>	= '18'		;* Big type
font<4>	= 1			;* Bold on
font<5> = 1			;* Italics
stat = Set_Printer('TEXTXY','BarCode Wall Sheet',2.5:@FM:-0.80,font,0)

bcFont = ''
bcFont<1> = '3 of 9 Barcode'
bcFont<2> = '24'
bcFont<3> = 'R'
bcFont<4> = '0'

FOR I = 1 TO 23
	IF I < 21 THEN
		stat = Set_Printer('TEXTXY',I,0.5:@FM:((I-1)*(.4) +.10),Font,0)	;* Added JCH
		stat = Set_Printer('TEXTXY','*':I:'*',1.5:@FM:((I-1)*(.4) +.10),bcFont,0)	;* Added JCH
	END
	
	IF I = 21 THEN
		stat = Set_Printer('TEXTXY','24',0.5:@FM:((I-1)*(.4) +.10),Font,0)	;* Added JCH
		stat = Set_Printer('TEXTXY','*24*',1.5:@FM:((I-1)*(.4) +.10),bcFont,0)	;* Added JCH
	END
	
	IF I = 22 THEN
		stat = Set_Printer('TEXTXY','25',0.5:@FM:((I-1)*(.4) +.10),Font,0)	;* Added JCH
		stat = Set_Printer('TEXTXY','*25*',1.5:@FM:((I-1)*(.4) +.10),bcFont,0)	;* Added JCH
	END
	
	IF I = 23 THEN
		stat = Set_Printer('TEXTXY','Null',0.5:@FM:((I-1)*(.4) +.10),Font,0)	;* Added JCH
		stat = Set_Printer('TEXTXY','* *',1.5:@FM:((I-1)*(.4) +.10),bcFont,0)	;* Added JCH
	END

NEXT I

stat = set_printer( 'TERM' )
RETURN


