Function Prod_Ver_Actions(Action, CalcColName, FSList, Handle, Name, FMC, Record, Status, OrigRecord, Param1, Param2, Param3, Param4, Param5, Param6, Param7, Param8, Param9, Param10)
/***********************************************************************************************************************

    This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
    permission from Infineon.

    Name        :   Prod_Ver_Actions

    Description :   Handles calculated columns and MFS calls for the current table.

    Notes       :   This function uses @ID, @RECORD, and @DICT to make sure {ColumnName} references work correctly.
                    If called from outside of a calculated column these will need to be set and restored.

    Parameters  :
        Action          [in] -- Name of the action to be taken
        CalcColName     [in] -- Name of the calculated column that needs to be processed. Normally this should only be
                                populated when the CalcField action is being used.
        FSList          [in] -- The list of MFSs and the BFS name for the current file or volume. This is an @SVM
                                delimited array, with the current MFS name as the first value in the array, and the BFS
                                name as the last value. Normally set by a calling MFS.
        Handle          [in] -- The file handle of the file or media map being accessed. Note, this does contain the
                                entire handle structure that the Basic+ Open statement would provide. Normally set by a
                                calling MFS.
        Name            [in] -- The name (key) of the record or file being accessed. Normally set by a calling MFS.
        FMC             [in] -- Various functions. Normally set by a calling MFS.
        Record          [in] -- The entire record (for record-oriented functions) or a newly-created handle (for
                                "get handle" functions). Normally set by a calling MFS.
        Status      [in/out] -- Indicator of the success or failure of an action. Normally set by the calling MFS but
                                for some actions can be set by the action handler to indicate failure.
        OrigRecord      [in] -- Original content of the record being processed by the current action. This is
                                automatically being assigned by the WRITE_RECORD and DELETE_RECORD actions within
                                BASE_MFS.
        Param1-10   [in/out] -- Additional request parameter holders
        ActionFlow     [out] -- Used to control the action chain (see the ACTION_SETUP insert for more information.)
                                Can also be used to return a special value, such as the results of the CalcField
                                method.

    History     :   (Date, Initials, Notes)
        07/28/10    dmb     Original programmer.
        10/13/10    dmb     Fix logic to extract the file handle if file has an index
        03/26/11    dmb     Add logic to save and restore @FILE.ERROR

***********************************************************************************************************************/

#pragma precomp SRP_PreCompiler

$insert LOGICAL
$insert FILE.SYSTEM.EQUATES
$insert ACTION_SETUP
$insert GAN_PARAM_CONFIG_EQUATES
$insert GAN_PARAMS_EQUATES

Declare Function   Database_Services, Gan_Services, Error_Services, SRP_Array
Declare Subroutine Database_Services

If KeyID then GoSub Initialize_System_Variables

Begin Case

    Case Action _EQC 'CalcField'            ;   GoSub Calc_Field
    Case Action _EQC 'READ_RECORD_PRE'      ;   GoSub READ_RECORD_PRE
    Case Action _EQC 'READ_RECORD'          ;   GoSub READ_RECORD
    Case Action _EQC 'READONLY_RECORD_PRE'  ;   GoSub READONLY_RECORD_PRE
    Case Action _EQC 'READONLY_RECORD'      ;   GoSub READONLY_RECORD
    Case Action _EQC 'WRITE_RECORD_PRE'     ;   GoSub WRITE_RECORD_PRE
    Case Action _EQC 'WRITE_RECORD'         ;   GoSub WRITE_RECORD
    Case Action _EQC 'DELETE_RECORD_PRE'    ;   GoSub DELETE_RECORD_PRE
    Case Action _EQC 'DELETE_RECORD'        ;   GoSub DELETE_RECORD
    Case Otherwise$                         ;   Status = 'Invalid Action'

End Case

If KeyID then GoSub Restore_System_Variables

If Assigned(ActionFlow) else ActionFlow = ACTION_CONTINUE$

Return ActionFlow


// ----- Calculated Columns --------------------------------------------------------------------------------------------
//
// The typical structure of a calculated column will look like this:
//
// Declare function TableName_Actions
//
// A = {COL1} ; * Reference as many data columns in this way to ensure the dictionary dependency is generated.
//
// @ANS = TableName_Actions('CalcField', 'CalcColName')
//
// ---------------------------------------------------------------------------------------------------------------------

Calc_Field:
    // Make sure the ActionFlow return variable is cleared in case nothing is calculated.
    ActionFlow = ''

    Begin Case
        Case CalcColName EQ 'EXPORT_CONTROL'    ; GoSub EXPORT_CONTROL
    End Case
return

EXPORT_CONTROL:
    PartNum         = {EPI_PART_NO}
    ExportControl   = Xlate('EPI_PART', PartNum, 'EXPORT_CONTROL', 'X')
    If ExportControl NE True$ then ExportControl = False$
    ActionFlow      = ExportControl
return


// ----- MFS calls -----------------------------------------------------------------------------------------------------

READ_RECORD_PRE:
    // In order to stop a record from being read in this action these lines of code must be used:
    //
    //    OrigFileError   = 100 : @FM : KeyID
    //    Status          = 0
    //    Record          = ''
    //    ActionFlow      = ACTION_STOP$
return

READ_RECORD:
    // In order to stop a record from being read in this action these lines of code must be used:
    //
    //    OrigFileError   = 100 : @FM : KeyID
    //    Status          = 0
    //    Record          = ''
return

READONLY_RECORD_PRE:
    // In order to stop a record from being read in this action these lines of code must be used:
    //
    //    OrigFileError   = 100 : @FM : KeyID
    //    Status          = 0
    //    Record          = ''
    //    ActionFlow      = ACTION_STOP$
return

READONLY_RECORD:
    // In order to stop a record from being read in this action these lines of code must be used:
    //
    //    OrigFileError   = 100 : @FM : KeyID
    //    Status          = 0
    //    Record          = ''
return

WRITE_RECORD_PRE:
return

WRITE_RECORD:
    
    PSNo        = {PROC_STEP_PSN}
    ReactorType = {REACT_TYPE}
    TechType    = Xlate('PROD_SPEC', PSNo, 'TECH_TYPE', 'X')
    If ( (ReactorType EQ 'GAN') and (TechType EQ 'P') ) then
        // Automatically create GAN_PARAM_CONFIG and GAN_PARAMS records if an Epi Part Number exists.
        // Can't check if CURR_PART_NO has changed because it is calculated.
        // Instead we will have to check if a CURR_PART_NO exists and if GAN_PARAM_CONFIG records exist for it.
        CurrPartNo = {EPI_PART_NO}
        If CurrPartNo NE '' then
            // Create GAN_PARAM_CONFIG records if they do not exist
            GaNParamStages = Database_Services('ReadDataRow', 'APP_INFO', 'GAN_PARAM_STAGES')
            GaNParamConfigKeys = ''
            For each Stage in GaNParamStages using @VM setting StageIndex
                GaNParamConfigKeys<StageIndex> = PSNo:'*':CurrPartNo:'*':Stage
            Next Stage
            If RowExists('GAN_PARAM_CONFIG', GaNParamConfigKeys) then
                // GAN_PARAM_CONFIG records exist. Just need to ensure Candela Total Defects is enabled.
                CanParamConfigKey = PSNo:'*':CurrPartNo:'*CAN_PRE'
                CanParamConfigRec = Database_Services('ReadDataRow', 'GAN_PARAM_CONFIG', CanParamConfigKey)
                If Error_Services('NoError') then
                    MetNames = CanParamConfigRec<GAN_PARAM_CONFIG.MET_NAME$>
                    Locate 'Candela Total Defects' in MetNames using @VM setting vPos then
                        CandelaTotalDefectsEnabled = CanParamConfigRec<GAN_PARAM_CONFIG.ENABLED$, vPos>
                        If CandelaTotalDefectsEnabled EQ False$ then
                            CanParamConfigRec<GAN_PARAM_CONFIG.ENABLED$, vPos> = True$
                            Database_Services('WriteDataRow', 'GAN_PARAM_CONFIG', CanParamConfigKey, CanParamConfigRec, True$, False$, True$)
                        end
                    end           
                end
                CanParamConfigKey = PSNo:'*':CurrPartNo:'*CAN_PST'
                CanParamConfigRec = Database_Services('ReadDataRow', 'GAN_PARAM_CONFIG', CanParamConfigKey)
                If Error_Services('NoError') then
                    MetNames = CanParamConfigRec<GAN_PARAM_CONFIG.MET_NAME$>
                    Locate 'Candela Total Defects Post' in MetNames using @VM setting vPos then
                        CandelaTotalDefectsEnabled = CanParamConfigRec<GAN_PARAM_CONFIG.ENABLED$, vPos>
                        If CandelaTotalDefectsEnabled EQ False$ then
                            CanParamConfigRec<GAN_PARAM_CONFIG.ENABLED$, vPos> = True$
                            Database_Services('WriteDataRow', 'GAN_PARAM_CONFIG', CanParamConfigKey, CanParamConfigRec, True$, False$, True$)
                        end
                    end           
                end
            end else
                // One or more GAN_PARAM_CONFIG records do not exist, so create them now. 
                ParameterList = Gan_Services('GetCurrPartParams', CurrPartNo)
                For each Stage in GaNParamStages using @VM setting StageIndex
                    ParamConfigKey = PSNo:'*':CurrPartNo:'*':Stage
                    If (RowExists('GAN_PARAM_CONFIG', ParamConfigKey) EQ False$) then
                        ParamConfigRec = ParameterList<StageIndex>
                        Convert @VM:@SVM to @FM:@VM in ParamConfigRec
                        ParamConfigRec = SRP_Array('Rotate', ParamConfigRec, @FM, @VM)
                        ThisParamList  = ParamConfigRec<GAN_PARAM_CONFIG.PARAM_NAME$>
                        // Enable Candela Total Defects.
                        For each Param in ThisParamList using @VM setting ParamPos
                            If ( (Param NE 'Candela Total Defects') and (Param NE 'Candela Total Defects Post') ) then
                                ParamConfigRec<GAN_PARAM_CONFIG.ENABLED$, ParamPos> = False$
                            end else
                                ParamConfigRec<GAN_PARAM_CONFIG.ENABLED$, ParamPos> = True$
                            end
                        Next Param
                        Database_Services('WriteDataRow', 'GAN_PARAM_CONFIG', ParamConfigKey, ParamConfigRec, True$, False$, True$)
                    end else
                        If ( (Stage EQ 'CAN') or (Stage EQ 'CAN_PRE') or (Stage EQ 'CAN_PST') ) then                               
                            CanParamConfigRec = Database_Services('ReadDataRow', 'GAN_PARAM_CONFIG', ParamConfigKey)
                            If Error_Services('NoError') then
                                MetNames = CanParamConfigRec<GAN_PARAM_CONFIG.MET_NAME$>
                                Locate 'Candela Total Defects' in MetNames using @VM setting vPos then
                                    CandelaTotalDefectsEnabled = CanParamConfigRec<GAN_PARAM_CONFIG.ENABLED$, vPos>
                                    If CandelaTotalDefectsEnabled EQ False$ then
                                        CanParamConfigRec<GAN_PARAM_CONFIG.ENABLED$, vPos> = True$
                                        Database_Services('WriteDataRow', 'GAN_PARAM_CONFIG', CanParamConfigKey, CanParamConfigRec, True$, False$, True$)
                                    end
                                end
                                Locate 'Candela Total Defects Post' in MetNames using @VM setting vPos then
                                    CandelaTotalDefectsEnabled = CanParamConfigRec<GAN_PARAM_CONFIG.ENABLED$, vPos>
                                    If CandelaTotalDefectsEnabled EQ False$ then
                                        CanParamConfigRec<GAN_PARAM_CONFIG.ENABLED$, vPos> = True$
                                        Database_Services('WriteDataRow', 'GAN_PARAM_CONFIG', CanParamConfigKey, CanParamConfigRec, True$, False$, True$)
                                    end
                                end           
                            end
                        end
                        
                    end
                Next Stage
            end
        end
    end
    
return

DELETE_RECORD_PRE:
return

DELETE_RECORD:
return


// ----- Internal Methods ----------------------------------------------------------------------------------------------

Initialize_System_Variables:
    // Save these for restoration later
    SaveDict        = @DICT
    SaveID          = @ID
    SaveRecord      = @RECORD
    OrigFileError   = @FILE.ERROR

    // Now make sure @DICT, ID, and @RECORD are populated
    CurrentDictName = ''
    If @DICT then
        DictHandle = @DICT<1, 2>
        Locate DictHandle in @TABLES(5) Using @FM Setting fPos then
            CurrentDictName = Field(@TABLES(0), @FM, fPos, 1)
        end
    end

    If CurrentDictName NE DictName then
         Open DictName to @DICT else Status = 'Unable to initialize @DICT'
    end    

    @ID = KeyID
    If Record else
        // Record might not have been passed in. Read the record from the database table just to make sure.
        @FILE.ERROR     = ''
        Open TableName to hTable then
            FullFSList  = hTable[1, 'F' : @VM]
            BFS         = FullFSList[-1, 'B' : @SVM]
            LastHandle  = hTable[-1, 'B' : \0D\]
            FileHandle  = \0D\ : LastHandle[1, @VM]

            Call @BFS(READO.RECORD, BFS, FileHandle, KeyID, FMC, Record, ReadOStatus)
        end
    end
    @RECORD = Record
return

Restore_System_Variables:
    Transfer SaveDict   to @DICT
    Transfer SaveID     to @ID
    Transfer SaveRecord to @RECORD
    @FILE.ERROR = OrigFileError
return
