Function Run_Stage_Wfr_Actions(Action, CalcColName, FSList, Handle, Name, FMC, Record, Status, OrigRecord, Param1, Param2, Param3, Param4, Param5, Param6, Param7, Param8, Param9, Param10)
/***********************************************************************************************************************

    This program is proprietary and is not to be used by or disclosed to others, nor is it to be copied without written
    permission from Infineon.

    Name        :   Run_Stage_Wfr_Actions

    Description :   Handles calculated columns and MFS calls for the current table.

    Notes       :   This function uses @ID, @RECORD, and @DICT to make sure {ColumnName} references work correctly.
                    If called from outside of a calculated column these will need to be set and restored.

    Parameters  :
        Action          [in] -- Name of the action to be taken
        CalcColName     [in] -- Name of the calculated column that needs to be processed. Normally this should only be
                                populated when the CalcField action is being used.
        FSList          [in] -- The list of MFSs and the BFS name for the current file or volume. This is an @SVM
                                delimited array, with the current MFS name as the first value in the array, and the BFS
                                name as the last value. Normally set by a calling MFS.
        Handle          [in] -- The file handle of the file or media map being accessed. Note, this does contain the
                                entire handle structure that the Basic+ Open statement would provide. Normally set by a
                                calling MFS.
        Name            [in] -- The name (key) of the record or file being accessed. Normally set by a calling MFS.
        FMC             [in] -- Various functions. Normally set by a calling MFS.
        Record          [in] -- The entire record (for record-oriented functions) or a newly-created handle (for
                                "get handle" functions). Normally set by a calling MFS.
        Status      [in/out] -- Indicator of the success or failure of an action. Normally set by the calling MFS but
                                for some actions can be set by the action handler to indicate failure.
        OrigRecord      [in] -- Original content of the record being processed by the current action. This is
                                automatically being assigned by the WRITE_RECORD and DELETE_RECORD actions within
                                BASE_MFS.
        Param1-10   [in/out] -- Additional request parameter holders
        ActionFlow     [out] -- Used to control the action chain (see the ACTION_SETUP insert for more information.)
                                Can also be used to return a special value, such as the results of the CalcField
                                method.

    History     :   (Date, Initials, Notes)
        08/24/20    djs     Original programmer.

***********************************************************************************************************************/

#pragma precomp SRP_PreCompiler

$Insert FILE.SYSTEM.EQUATES
$Insert ACTION_SETUP
$Insert APP_INSERTS
$Insert RUN_STAGE_WFR_EQUATES
$INSERT GAN_STAGE_CYCLE_TIME_EQUATES
$Insert WO_WFR_EQUATES

Equ COMMA$ to ','

Declare function    Error_Services, Database_Services, OBJ_GAN_CYCLE_TIME, Environment_Services, Logging_Services, Datetime, Gan_Services
Declare subroutine  Error_Services, Database_Services, Logging_Services, Obj_Tables

LogPath     = Environment_Services('GetApplicationRootPath') : '\LogFiles\GAN_CYCLE_TIME'
LogDate     = Oconv(Date(), 'D4/')
LogTime     = Oconv(Time(), 'MTS')
LogFileName = LogDate[7, 4] : '-' : LogDate[1, 2] : '-' : LogDate[4, 2] : ' GAN_CYCLE_TIME.csv'
Headers     = 'Logging DTM' : @FM : 'User' : @FM : 'Notes'
objLog      = Logging_Services('NewLog', LogPath, LogFileName, CRLF$, Comma$, Headers, '', False$, False$)
LoggingDTM  = LogDate : ' ' : LogTime   ; // Logging DTM 

If KeyID then GoSub Initialize_System_Variables


Begin Case
	
	Case Action _EQC 'CalculateColumn'      ;   GoSub CalculateColumn
	Case Action _EQC 'READ_RECORD_PRE'      ;   GoSub READ_RECORD_PRE
	Case Action _EQC 'READ_RECORD'          ;   GoSub READ_RECORD
	Case Action _EQC 'READONLY_RECORD_PRE'  ;   GoSub READONLY_RECORD_PRE
	Case Action _EQC 'READONLY_RECORD'      ;   GoSub READONLY_RECORD
	Case Action _EQC 'WRITE_RECORD_PRE'     ;   GoSub WRITE_RECORD_PRE
	Case Action _EQC 'WRITE_RECORD'         ;   GoSub WRITE_RECORD
	Case Action _EQC 'DELETE_RECORD_PRE'    ;   GoSub DELETE_RECORD_PRE
	Case Action _EQC 'DELETE_RECORD'        ;   GoSub DELETE_RECORD
	Case Otherwise$                         ;   Status = 'Invalid Action'
		
End Case

If KeyID then GoSub Restore_System_Variables

If Assigned(ActionFlow) else ActionFlow = ACTION_CONTINUE$

Return ActionFlow


////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Calculated Columns 
//
// The typical structure of a calculated column will look like this:
//
// Declare function Database_Services
//
// @ANS = Database_Services('CalculateColumn')
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

CalculateColumn:
	
	// Make sure the ActionFlow return variable is cleared in case nothing is calculated.
	ActionFlow = ''
	
	Begin Case
		Case CalcColName EQ 'EXAMPLE'            ; GoSub EXAMPLE
	End Case
	
return


EXAMPLE:
	
	ActionFlow  = False$ ; // This is your return or response variable
	
return

// ----- MFS calls -----------------------------------------------------------------------------------------------------

READ_RECORD_PRE:
	// In order to stop a record from being read in this action these lines of code must be used:
	//
	//    OrigFileError   = 100 : @FM : KeyID
	//    Status          = 0
	//    Record          = ''
	//    ActionFlow      = ACTION_STOP$
return

READ_RECORD:
	// In order to stop a record from being read in this action these lines of code must be used:
	//
	//    OrigFileError   = 100 : @FM : KeyID
	//    Status          = 0
	//    Record          = ''
return

READONLY_RECORD_PRE:
	// In order to stop a record from being read in this action these lines of code must be used:
	//
	//    OrigFileError   = 100 : @FM : KeyID
	//    Status          = 0
	//    Record          = ''
	//    ActionFlow      = ACTION_STOP$
return

READONLY_RECORD:
	// In order to stop a record from being read in this action these lines of code must be used:
	//
	//    OrigFileError   = 100 : @FM : KeyID
	//    Status          = 0
	//    Record          = ''
return

WRITE_RECORD_PRE:
	
return

WRITE_RECORD:
	OrigSigDTMs = OrigRecord<RUN_STAGE_WFR_SIA_COMP_DTM$>
	NewSigDTMs  = Record<RUN_STAGE_WFR_SIA_COMP_DTM$>
	CompTime = NewSigDTMs<1,2>
	Status = Record<RUN_STAGE_WFR_STATUS$>
	FmtRecKey = @ID
	Swap '*' with @FM in FmtRecKey
	RDSNo = FmtRecKey<1>
	Stage = FmtRecKey<2>
	WfrID = FmtRecKey<3>
		
		***************SPLIT STEP******
	
	IF Stage EQ 'SPLIT' AND (Status EQ 'DISP' OR Status EQ 'CHAR') then
		IF Gan_Services('GetRunSplitStatus', RDSNo) then
			GanStageCycleTimeRecKey = RDSNo : '*' : Stage
			GanStageCycleTimeRec = XLATE('GAN_STAGE_CYCLE_TIME', GanStageCycleTimeRecKey, '', 'X')
			RecordExists = ''
			IF GanStageCycleTimeRec NE '' then
				RecordExists = 1
			end else
				RecordExists = 0
			end
			//Find the start time from the WO_WFR Record
			StartTime = ''
			StopTime = ''
			WoWfrKey = WfrID
			swap '.' with '*' in WoWfrKey 
			WoWfrRec = XLATE('WO_WFR', WoWfrKey, '', 'X')			
			//The stop time will be the LOC_DTM for the next stage so we find the position for the split then +1 for the 
			//start of the next step
			LOCATE 'GCH*SPLIT_Q' in WoWfrRec<WO_WFR_INV_LOC$> setting SplitPos then
				StartTime = WoWfrRec<1,SplitPos>
				StopIndex = SplitPos + 1
				StopTime = Record<RUN_STAGE_WFR_COMP_DTM$>			
				//Basic record variables
				StartDTM = StartTime
				StopDTM = StopTime
				OperatorStart = WoWfrRec<WO_WFR_LOC_BY$,SplitPos>
				OperatorStop = WoWfrRec<WO_WFR_LOC_BY$,StopIndex>
				StageName = Stage
				Tool = Record<RUN_STAGE_WFR_TOOL_ID$>
				ToolClass = Record<RUN_STAGE_WFR_SPEC_TOOL_CLASS$>
				Exported = 0
				RecordTime = Datetime()
		
				GanStageCycleTimeRec<GAN_STAGE_CYCLE_TIME_STAGE$> = Stage
				GanStageCycleTimeRec = Insert(GanStageCycleTimeRec, GAN_STAGE_CYCLE_TIME_START$, 1, 0, StartDTM)
				GanStageCycleTimeRec = Insert(GanStageCycleTimeRec, GAN_STAGE_CYCLE_TIME_STOP$, 1, 0, StopDTM)
				GanStageCycleTimeRec = Insert(GanStageCycleTimeRec, GAN_STAGE_CYCLE_TIME_WFR_ID$, 1, 0, WfrID)
				GanStageCycleTimeRec<GAN_STAGE_CYCLE_TIME_RUN_CREATION_DATE$> = RecordTime
				GanStageCycleTimeRec<GAN_STAGE_CYCLE_TIME_OPERATOR_START$> = OperatorStart
				GanStageCycleTimeRec<GAN_STAGE_CYCLE_TIME_OPERATOR_STOP$> = OperatorStop
				GanStageCycleTimeRec<GAN_STAGE_CYCLE_TIME_TOOL$> = Tool
				GanStageCycleTimeRec<GAN_STAGE_CYCLE_TIME_TOOL_CLASS$> = ToolClass
				GanStageCycleTimeRec<GAN_STAGE_CYCLE_TIME_RDS_NO$> = RDSNo				
				Obj_Tables('WriteRec', 'GAN_STAGE_CYCLE_TIME':@RM:GanStageCycleTimeRecKey:@RM:@RM:GanStageCycleTimeRec)
			end  
	    end
	end
	
	****************End Split Step***************
	
	If OrigSigDTMs NE NewSigDTMs then
	    
		InvActions = Record<RUN_STAGE_WFR_SPEC_INV_ACTION$>
			Status = Record<RUN_STAGE_WFR_STATUS$>
			
			GanStageCycleTimeRecKey = RDSNo : '*' : Stage
			GanStageCycleTimeRec = XLATE('GAN_STAGE_CYCLE_TIME', GanStageCycleTimeRecKey, '', 'X')
			RecordExists = ''
			
			IF GanStageCycleTimeRec NE '' then
				RecordExists = 1
			end else
				RecordExists = 0
			end
			
			Locate 'STOP' in InvActions using @VM setting iPos then
				
				StartDTM = NewSigDTMs<1,1>
				StopDTM = NewSigDTMs<1,2>
				OperatorStart = Record<RUN_STAGE_WFR_SIA_COMP_BY$, 1>
				OperatorStop = Record<RUN_STAGE_WFR_SIA_COMP_BY$, 2>
				StageName = Stage
				Tool = Record<RUN_STAGE_WFR_TOOL_ID$>
				ToolClass = Record<RUN_STAGE_WFR_SPEC_TOOL_CLASS$>
				Exported = 0
				//RecordTime = GetTickCount()
				RecordTime = Datetime()
				
				GanStageCycleTimeRec<GAN_STAGE_CYCLE_TIME_STAGE$> = Stage
				GanStageCycleTimeRec = Insert(GanStageCycleTimeRec, GAN_STAGE_CYCLE_TIME_START$, 1, 0, StartDTM)
				GanStageCycleTimeRec = Insert(GanStageCycleTimeRec, GAN_STAGE_CYCLE_TIME_STOP$, 1, 0, StopDTM)
				GanStageCycleTimeRec = Insert(GanStageCycleTimeRec, GAN_STAGE_CYCLE_TIME_WFR_ID$, 1, 0, WfrID)
				GanStageCycleTimeRec<GAN_STAGE_CYCLE_TIME_RUN_CREATION_DATE$> = RecordTime
				GanStageCycleTimeRec<GAN_STAGE_CYCLE_TIME_OPERATOR_START$> = OperatorStart
				GanStageCycleTimeRec<GAN_STAGE_CYCLE_TIME_OPERATOR_STOP$> = OperatorStop
				GanStageCycleTimeRec<GAN_STAGE_CYCLE_TIME_TOOL$> = Tool
				GanStageCycleTimeRec<GAN_STAGE_CYCLE_TIME_TOOL_CLASS$> = ToolClass
				GanStageCycleTimeRec<GAN_STAGE_CYCLE_TIME_RDS_NO$> = RDSNo
				if CompTime NE '' then
					LogData       = ''
					LogData<1>    = ''
					LogData<2, 1> = LoggingDTM
					LogData<2, 2> = @User4
					LogData<3>    = 'COMP detected in record, creating GAN_STAGE_CYCLE_TIME record. Stage is ' : Stage : '. RDS # is ' : RDSNo : '. Stop time is ' : StopDTM : '. Record Exists = ' : RecordExists : '. ' :@ID
					Logging_Services('AppendLog', objLog, LogData, @FM, @VM)
					Obj_Tables('WriteRec', 'GAN_STAGE_CYCLE_TIME':@RM:GanStageCycleTimeRecKey:@RM:@RM:GanStageCycleTimeRec)
				end
			end
	end
	LogData       = ''
	LogData<1>    = '*** Stop Logging for Run_stage_wfr_actions ***'
	Logging_Services('AppendLog', objLog, LogData, @FM, @VM)
return

DELETE_RECORD_PRE:
return

DELETE_RECORD:
return

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Internal GoSubs
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

ClearCursors:
	For counter = 0 to 8
		ClearSelect counter
	Next counter
return


Initialize_System_Variables:
	
	// Save these for restoration later
	SaveDict        = @DICT
	SaveID          = @ID
	SaveRecord      = @RECORD
	OrigFileError   = @FILE.ERROR
	
	// Now make sure @DICT, ID, and @RECORD are populated
	CurrentDictName = ''
	If @DICT then
		DictHandle = @DICT<1, 2>
		Locate DictHandle in @TABLES(5) Using @FM Setting fPos then
			CurrentDictName = Field(@TABLES(0), @FM, fPos, 1)
		end
	end
	
	If CurrentDictName NE DictName then
		Open DictName to @DICT else Status = 'Unable to initialize @DICT'
	end    
	
	@ID = KeyID
	If Record else
		// Record might not have been passed in. Read the record from the database table just to make sure.
		@FILE.ERROR     = ''
		Open TableName to hTable then
			FullFSList  = hTable[1, 'F' : @VM]
			BFS         = FullFSList[-1, 'B' : @SVM]
			LastHandle  = hTable[-1, 'B' : \0D\]
			FileHandle  = \0D\ : LastHandle[1, @VM]
			
			Call @BFS(READO.RECORD, BFS, FileHandle, KeyID, FMC, Record, ReadOStatus)
		end
	end
	@RECORD = Record
	
return


Restore_System_Variables:
	
	Transfer SaveDict   to @DICT
	Transfer SaveID     to @ID
	Transfer SaveRecord to @RECORD
	@FILE.ERROR = OrigFileError
	
return
